（原创）多工作表两（多）条件汇总 - SUMIFS函数

dengjq2000

    论坛里有很多针对多工作表单条件进行汇总要求通过公式来实现的求助主题，该方面的主题通常可以借助公式：SUMPRODUCT+SUMIF+INDIRECT 或：数组公式：SUM+SUMIF+INDIRECT 来很好的实现。

    可是对于多工作表双条件或更多条件汇总时，就不能借助上面两种方式来实现，一般需借助VBA或SQL语句来实现。但VBA与SQL语句对于大部分E菜鸟们还是有点高深。

现在介绍通过EXCEL 2007新增加的 SUMIFS 函数来实现。

    具体下：

    三张原始数据源工作表，分别为：Sheet1、Sheet2、Sheet3。

工作表：Sheet1 原始数据有：

部门	规格	型号	进货量
A	T型	TDR34-01	1
B	B型	BDR40-01	2
C	A型	ADR50-01	3
A	A型	ADR50-01	7
C	T型	TDR34-01	8
B	A型	ADR50-01	9
B	T型	TDR35-01	10
A	B型	BDR40-01	11
A	A型	ADR50-02	7
A	T型	TDR35-01	20
B	T型	TDR34-01	23
A	A型	ADR45-01	20
A	A型	ADR50-02	50

工作表：Sheet2 原始数据有：

部门	规格	型号	进货量
A	T型	TDR34-01	10
B	B型	BDR40-01	25
C	A型	ADR50-01	38
A	A型	ADR50-01	57
C	T型	TDR34-01	82
B	A型	ADR50-01	29
B	T型	TDR35-01	210
A	B型	BDR40-01	191
A	A型	ADR50-02	25
A	T型	TDR35-01	60
B	T型	TDR34-01	58
A	A型	ADR45-01	46
B	A型	ADR50-02	35
C	T型	TDR35-01	200

工作表：Sheet3 原始数据有：

部门	规格	型号	进货量
A	T型	TDR34-01	51
B	B型	BDR40-01	52
C	A型	ADR50-01	53
A	A型	ADR50-01	57
C	T型	TDR34-01	58
B	A型	ADR50-01	59
B	T型	TDR35-01	60
C	B型	BDR40-01	61
A	A型	ADR50-02	10
A	T型	TDR35-01	52
B	T型	TDR34-01	64
A	A型	ADR45-01	77
B	A型	ADR50-02	27

如果只单条件：“部门”进行多工作表的“进货量”汇总，这可以用公式（也是论坛已有的解法）：

1. =SUM(SUMIF(INDIRECT("Sheet"&ROW($1:$3)&"!A:A"),A2,INDIRECT("Sheet"&ROW($1:$3)&"!D:D")))

复制代码

来实现。

    可是对于双条件：“部门”及“规格”进行对多工作表“进货量”汇总时，借助 SUMIF 函数是实现不了，一般需借助VBA（暂没列出）或SQL语句（具体见附件两工作表：“部门规格双条件汇总SQL”与“三条件汇总SQL”的效果）来实现。但VBA与SQL语句对于大部分E菜鸟们还是有点高深。

    幸运的是，在EXCEL 2007版本新增了的 SUMIFS 函数可以帮我们解决这个问题：

公式：

1. =SUMPRODUCT(SUMIFS(INDIRECT("Sheet"&ROW($1:$3)&"!D:D"),INDIRECT("Sheet"&ROW($1:$3)&"!A:A"),A2,INDIRECT("Sheet"&ROW($1:$3)&"!B:B"),B2))

复制代码

或数组公式：

1. =SUM(SUMIFS(INDIRECT("Sheet"&ROW($1:$3)&"!D:D"),INDIRECT("Sheet"&ROW($1:$3)&"!A:A"),A2,INDIRECT("Sheet"&ROW($1:$3)&"!B:B"),B2))

复制代码

继续追溯：

可想而知，如果三个条件或更多的条件进行多工作表汇总时，只需在条件区域增加相应的条件即可。像三条件：“部门”、“规格”及“型号”进行对多工作表“进货量”汇总时。

则公式为（数组公式不列出）：

1. =SUMPRODUCT(SUMIFS(INDIRECT("Sheet"&ROW($1:$3)&"!D:D"),INDIRECT("Sheet"&ROW($1:$3)&"!A:A"),A2,INDIRECT("Sheet"&ROW($1:$3)&"!B:B"),B2,INDIRECT("Sheet"&ROW($1:$3)&"!C:C"),C2))

复制代码

该贴已经同步到 dengjq2000的微博

DZ潇潇

作为V盲和S盲的表弟，这贴很适合偶。先睹为快，占楼学习

看见星光

以前习惯用sumproduct，最近SUMIFS越用越顺手了。~~

dengjq2000

以下是很好引用该主题解决的问题的的主题连接链：


1、关于多条件多工作表求和的问题

2、如何根据筛选的年月求当年总和

3、单元条件多个工作表中数据汇总求和

4、运用函数按条件自动计算结余库存

=SUMPRODUCT(SUMIF(INDIRECT("Sheet"&ROW($1:$2)&"!A:A"),A2,INDIRECT("Sheet"&ROW($1:$2)&"!E1"))*{1;-1})

5、多个表之间的计算问题

6、关于同一格式 不同表格 数据汇总的问题

7、如何跨月统计？

计算多工作表时间段区域段数据汇总一个不错解法（"工作表表名不规律情况下的书写方式"）：

=SUM(SUMIF(INDIRECT({"2014年收入";"2015年收入"}&"!C:C"),">="&DATE(LEFT($E$1,4),ROW(A1)-{1,0},21),INDIRECT({"2014年收入";"2015年收入"}&"!D:D"))*{1,0})

8、多表汇总（不规则）求和


首次嵌入OFFSET函数（6楼）：

=SUMPRODUCT(SUMIF(INDIRECT(ROW($6:$9)&"月!A:A"),A2,OFFSET(INDIRECT(ROW($6:$9)&"月!A:A"),,{4;5;3;4})))

dajiahaoxinku12

支持原创，感谢邓版分享      

不自放逸

支持原创，感谢楼主

xpm130

感谢邓版总结分享!

陈坚平0219

如果表名不规则，例如 为 数据表和原始数据呢 如何做到？

xutianlin

这帖子不错，我函数多维引用比较薄弱

zxd_little

前辈，我去里空间里面不能给留言啊，说没权限啊。老师，挣点财富值不容易啊，我才100的财富值，等到财富值换课卷报班呢，你就原谅我把。我也不是灌水啊，其实我还是下下来看了的，有些东西是学习了啊。只是没有换一些说法啊。以后我回复的时候，就写清楚吧，学习到什么东西了，比如你写的sumifs，countifs啊，对这些加深印象这些了。感谢前辈了，其实就是挣财富值有点麻烦啊，快乐答题我做过几次，有时候你做了10分钟，还没有回复别个2个问题得到的财富值多，希望前辈们整理一个关于每个章节的pdf吧，那样我们就可以看那个pdf，然后加深印象的去做题赛，做了题，就有财富值了啊。