148字符无缺陷人民币金额大写公式 逆天了！

cbtaja

最后，从分析人民币金额构成的数值三部分（即①、符号，②、整数部分，③小数部分）的既相对独立又存在关联制约的特征出发，终于得出一个堪称完美的三段式公式（165字）：

1. =TEXT(RMB(A2,2),";负;零元")&TEXT(INT(ABS(A2)+0.5%),"[dbnum2]G/通用格式元;;")&SUBSTITUTE(SUBSTITUTE(TEXT(RIGHT(RMB(A2,2),2),"[dbnum2]0角0分;;整"),"零分","整"),"零角",IF(A2^2<1,,"零"))

复制代码

这个公式不仅完全符合票据填写的有关规定，而且也完全符合人们的语言习惯，与国产软件WPS提供的内置人民币大写结果完全一致，而且在符合前面这两个条件的同时，其字符数也达到了最省。

补充内容 (2014-7-13 11:27):
再精简掉1个字（仅164字）：
=TEXT(A2+0.5%,";负;负")&TEXT(INT(ABS(A2)+0.5%),"[dbnum2]G/通用格式元;;零元")&SUBSTITUTE(SUBSTITUTE(TEXT(RIGHT(RMB(A2,2),2),"[dbnum2]0角0分;;整"),"零分","整"),"零角",IF(A2^2

补充内容 (2014-9-26 09:41):
对补充的更正：TEXT(RMB(E3,2),";负")&TEXT(INT(ABS(E3)+0.5%),"[dbnum2]G/通用格式元;;零元")&SUBSTITUTE(SUBSTITUTE(TEXT(RIGHT(RMB(E3,2),2),"[dbnum2]0角0分;;整"),"零分","整"),"零角",IF(E3^2<1,,"零"

补充内容 (2015-4-23 12:42):
再精简：
=IF(A2>-0.5%,"","负")&TEXT(INT(ABS(A2)+0.5%),"[dbnum2]G/通用格式元;;零元")&SUBSTITUTE(SUBSTITUTE(TEXT(RIGHT(RMB(A2,2),2),"[dbnum2]0角0分;;整"),"零分","整"),"零角",IF(A2^2<1,,"零"))

补充内容 (2015-4-23 13:02):
再减少2字符：
=IF(A2>-0.5%,,"负")&TEXT(INT(ABS(A2)+0.5%),"[dbnum2]G/通用格式元;;零元")&SUBSTITUTE(SUBSTITUTE(TEXT(RIGHT(RMB(A2,2),2),"[dbnum2]0角0分;;整"),"零分","整"),"零角",IF(A2^2<1,,"零"))

cslrxyz

我总觉得五分就是五分，没必要写成什么“零元零五分”这不科学

cbtaja

在上面的148字和165字公式中，都以两个字符连接运算符&把公式分成3个部分，即①符号部分，②整数部分，③小数部分，因此我称之为“三段式”金额大写公式。其特点是公式结构非常简单、清晰，因此很容易让人看明白。

cbtaja

最后，下结论：
如仅以满足人民银行关于票据填写的基本规定为准，则以17楼的148字符公式为最优，
如在此之上还增加一条要求：还要完全符合人们语言习惯，则以21楼的165字符公式为最优。

或者，如果你不相信这个结论的话，那么你可以尝试在同样的条件下做一个更精短的公式来{:soso_e112:}

一剑惊心

没听说过0.05元大写写成零元零伍分的，WPS的自定义格式也只是显示伍分，况且没处理空格的情况啊

cbtaja

一剑惊心 发表于 2013-10-31 15:34
没听说过0.05元大写写成零元零伍分的，WPS的自定义格式也只是显示伍分，况且没处理空格的情况啊

0.05元的大写可否为“零元零伍分”，当以中国人民银行会计司编写的最新《企业、银行正确办理支付结算指南》中对“正确填写票据和结算凭证的基本规定”的回答为准（该内容在18楼有引述），不以个人是否听说过为准。
至于空格还要转换为大写金额的，之前我也没听说过，所以让你见笑了。

qigengzier

这么多软条件，140多字符和170多字符之间的30字符差距完全可以割除，谈不上逆天。
放在同一个标准下，简化长度，才能谈逆天。根据中国人民银行会计司编写的最新XXXXX，我没看过哈，自己挑这么多软条件，正常大多人接受的也是0.05为伍分。其实就没必要再简化成这样的。
个人觉得

haoxie_8

请教个问题，179字公式中：
  IF(-RMB(A2,2),TEXT(A2,";负")     这里为什么不能写成   IF(-RMB(A2,2),"负")

haoxie_8

179字公式中：
  +0.5%是什么目的？

hellohaha

太浪费脑细胞了。牛！