标识重复项，函数

笑着...两年过去

笑着.zip (5.69 KB, 下载次数: 58)

2013-9-8 13:10 上传

点击文件名下载附件

ykqrs

1. =TEXT(SUM((MMULT(N(COUNTIF(OFFSET($A$1:$C$1,ROW($1:$90),),A2:C2)={1,1,1}),{1;1;1})=3)*1),"[>1]重复;")

复制代码

笑着...两年过去

ykqrs 发表于 2013-9-8 14:38

漂亮，countif处理，学习了

ykqrs

jsxjd  每行的三个不能重复吧？  发表于 2013-9-8 17:54

笑着的附件中没有这种情况，如果有可以给一个有局限性的公式，

1. =TEXT(SUM(1*ISERR(0/MMULT(5^IF(N(IF({1},A2:C2)),A2:C2,CODE(A2:C2))-5^IF(N(IF({1},A$2:C$91)),A$2:C$91,CODE(A$2:C$91)),{1;1;1}))),"[>1]重复;")

复制代码

文字和字母仅限一位
AmoKat老师曾经写过这么一个类似的公式

笑着...两年过去

ykqrs 发表于 2013-9-9 07:54
笑着的附件中没有这种情况，如果有可以给一个有局限性的公式， 文字和字母仅限一位
AmoKat老师曾经写过这 ...

试试这个

1. =TEXT(SUM(N(0=MMULT((-ISERR(FIND("/"&A2:C2&"/","/"&A:A&"/"&B:B&"/"&C:C&"/"))),{1;1;1}))),"[>1]重复;")

复制代码

ykqrs

笑着...两年过去 发表于 2013-9-9 09:17
试试这个

看了。。。。。。。。
3        3        3
3        0        0
测试一下。。。。。。。。。。。。。。。。

笑着...两年过去

ykqrs 发表于 2013-9-9 09:43
看了。。。。。。。。
3        3        3
3        0        0

有点意思，没发觉，再试试

AmoKat

是純數字或英數混合?

如果純數字時

1. =TEXT(SUMPRODUCT(--(SUM(A2:C2^7)=MMULT(A$2:C$91^7,{1;1;1}))),"[>1]重複;")

复制代码

笑着...两年过去

AmoKat 发表于 2013-9-9 16:01
是純數字或英數混合?

如果純數字時

这个不错，简单

AmoKat

如果是文數字混合時
三值可能重複時

1. =TEXT(SUM(--(MMULT(COUNTIF(A2:C2,A$2:C$91),{1;1;1})=MMULT(COUNTIF(A2:C2,A2:C2),{1;1;1}))),"[>1]重複;")

复制代码

三值不重複時

1. =TEXT(SUM(--(MMULT((A2:C2=A$2:A$91)+(A2:C2=B$2:B$91)+(A2:C2=C$2:C$91),{1;3;5})=9)),"[>1]重複;")

复制代码