日期格式非标准, 如何计算周期?

lyliyu

入库日期                   出库日期                 在库时间(以天计算)
13-7-17 PM6:34        13-7-17 PM7:18           #VALUE!
13-7-17 PM6:11        13-7-17 PM6:39       
13-7-17 PM5:44        13-7-17 PM6:37       
13-7-17 PM5:33        13-7-17 PM6:03       

第1列和第2列都是从系统上导出的,无法更改, 希望能在C列用公式计算出在库时间(比如: 0.4天)

第1列和第2列的日期格式与EXCEL不兼容, EXCEL会认为是文本,不是日期格式.
直接B2-A2, 结果是错误#VALUE!

需求: 计算出在库时间.  详见附件的文件

请大侠帮助!

zheng_0925

0.4天不对吧

1. =SUMPRODUCT((MID(MIDB(A2:B2,9,9),3,9)+IF(ISERR(FIND("PM",A2:B2)),,12)/24)*{-1,1})
   

复制代码

cleverzhzhf

1. =(REPLACE(B2,FIND(" ",B2)+1,2,)&TEXT(FIND("PM",B2&"PM")-12," A\M; P\M"))-(REPLACE(A2,FIND(" ",A2)+1,2,)&TEXT(FIND("PM",A2&"PM")-12," A\M; P\M"))

复制代码

普通公式

————————————————————————————————————————————————————————————————————————--——
简化一点：

1. 
   
2. =SUM((REPLACE(A2:B2,FIND(" ",A2:B2)+1,2,)&TEXT(FIND("PM",A2:B2&"PM")-12," A\M; P\M"))*{-1,1})

复制代码

数组公式

fjh19880625

=SUMPRODUCT((MID(A2:B2,1,FIND("M",A2:B2)-2)--MID(A2:B2,FIND("M",A2:B2)+1,99)+MIN(IFERROR(FIND("P",A2:B2),0),0.5))*{-1,1})

丢丢表格

?????????????
先看看再说

cleverzhzhf

fjh19880625 发表于 2013-7-18 14:01
=SUMPRODUCT((MID(A2:B2,1,FIND("M",A2:B2)-2)--MID(A2:B2,FIND("M",A2:B2)+1,99)+MIN(IFERROR(FIND("P",A2 ...

在第59行之后出现错误。
主要在于“PM12:15”之类的数据，这个数字，实际上比“PM1:15”要小一小时。

cleverzhzhf

丢丢表格 发表于 2013-7-18 14:05
c2=SUMPRODUCT((SUBSTITUTE(SUBSTITUTE(A2:B2,"PM",),"AM",)+COUNTIF(A2:A2:B2,{"AM";"PM"})*{1,1.5})*{-1, ...

丢丢老师，您的式子也还存在些问题。

cleverzhzhf

zheng_0925 发表于 2013-7-18 13:53
0.4天不对吧

您的计算结果好像都没有超过0.5的

cleverzhzhf

连发三个帖子都被删了。。。郁闷。。。
大家在计算的时候，需要注意一下，在日期记录习惯上，PM12:15要比PM1:15早一个小时，不是晚11个小时。

准提部林

试试．Ｃ２一般公式：

1. 
   
2. =MMULT(--(REPLACE(A2:B2,FIND(" ",A2:B2)+1,2,)&MID(A2:B2,FIND(" ",A2:B2),3)),{-1;1})

复制代码