如何提取文本中最后一串数字

wenger

如题，多谢了！这个问题也困扰了很久。
如何提取最后一串数字.zip (6.93 KB, 下载次数: 80)

2013-6-26 00:46 上传

点击文件名下载附件

袁勇

结果3：

=MAX(--TEXT(RIGHT(A2,ROW($1:$9)),"0.##;;;!0"))
数组公式，ctrl+shift+回车键结束公式！！

wshcw

数组公式:
=-LOOKUP(1,-RIGHT(LEFT(A2,MATCH(1,-MID(A2,ROW($1:$256),1))),ROW($1:$15)))

Bodhidharma

wshcw 发表于 2013-6-26 01:17
数组公式:
=-LOOKUP(1,-RIGHT(LEFT(A2,MATCH(1,-MID(A2,ROW($1:$256),1))),ROW($1:$15)))

利用match和lookup的特性使用”-”來找最後一個符合的值，用的真漂亮！
不過最好加一個substitute處理”,"的問題

1. =-LOOKUP(1,-RIGHT(SUBSTITUTE(LEFT(A2,MATCH(1,-MID(A2,ROW($1:$256),1))),",",""),ROW($1:$15)))

复制代码

256是整個字串的最大長度（可自行加大）
15是數字字串的最大長度（可自行加大）

wenger

Bodhidharma 发表于 2013-6-26 01:38
利用match和lookup的特性使用”-”來找最後一個符合的值，用的真漂亮！
不過最好加一個substitute處理” ...

万分感谢，都是高手啊！
能帮我看看这个问题吗？多谢！也是困扰我很久的问题。http://club.excelhome.net/thread-1030046-1-1.html，关键是前面的文本中包含特殊字符怎么办？比如;、@%等。非常感谢！

wenger

wshcw 发表于 2013-6-26 01:17
数组公式:
=-LOOKUP(1,-RIGHT(LEFT(A2,MATCH(1,-MID(A2,ROW($1:$256),1))),ROW($1:$15)))

万分感谢，高手啊！

ykqrs

1. =LOOKUP(9E+307,--RIGHT(A2,ROW($1:$15)))

复制代码

wenger

ykqrs 发表于 2013-6-26 08:47

谢谢！对于最后一位不是数字的话貌似无法解决...

wshcw

wenger 发表于 2013-6-26 08:30
万分感谢，高手啊！

如果数字在最右边时，公式可简化为：

1. =-LOOKUP(,-RIGHT(A2,ROW($1:$15)))

复制代码

或者用数组公式：

1. =RIGHT(A2,COUNT(-RIGHT(A2,ROW($1:$15))))

复制代码

wenger

wshcw 发表于 2013-6-26 01:17
数组公式:
=-LOOKUP(1,-RIGHT(LEFT(A2,MATCH(1,-MID(A2,ROW($1:$256),1))),ROW($1:$15)))

该算法如果最后一串数字为负值的话貌似无法计算。