帮我做一个带拼音的字符的繁简转换啊

pbdq

我在弄一部佛经，

结果想把里面加了拼音的繁体批量转换为简体，应该怎么做？

具体看附件

汗死，居然无法上传大于1M的，只好自己传一个。

点此下载  http://www.foyuan.cn/%e6%a5%9e%e4%b8%a5%e7%bb%8f%e6%8b%bc%e9%9f%b3%e7%89%88.doc

下载地址

pbdq

{:soso_e100:}在线等{:soso_e100:}

MicrosoftEH

关注学习... ...

pbdq

没有大仙帮忙啊，顶上去

sylun

可以试试如下代码。因文档较长，处理时间也会较长:

1. Sub test()
   
2.     Dim TempRange As Range
   
3.     Dim aField As Field
   
4.     Dim strChinese As String
   
5.     Dim i As Long
   
6.     Dim n As Long
   
7.    
   
8.     Application.ScreenUpdating = False
   
9.     Set TempRange = ActiveDocument.Bookmarks("\endofdoc").Range
   
10.     For Each aField In ActiveDocument.Fields
    
11.         If aField.Type = wdFieldFormula Then
    
12.             strChinese = aField.Code.Characters.Last.Previous.Text
    
13.             With TempRange
    
14.                 .Text = strChinese
    
15.                 .Select
    
16.                 .TCSCConverter wdTCSCConverterDirectionTCSC
    
17.                 .End = .End + 1
    
18.                 If .Text <> strChinese Then
    
19.                     aField.Code.Characters.Last.Previous.Text = .Text
    
20.                     n = n + 1
    
21.                 End If
    
22.                 i = i + 1
    
23.             End With
    
24.         End If
    
25.     Next
    
26.     TempRange.Text = Empty
    
27.     MsgBox "处理完毕。共对" & i & "个Eq域中的" & n & "个进行了中文繁简转换。"
    
28.     Application.ScreenUpdating = True
    
29. End Sub

复制代码

：

pbdq

sylun 发表于 2013-6-17 17:05
可以试试如下代码。因文档较长，处理时间也会较长:：

感谢大仙救命之恩。

pbdq

sylun 发表于 2013-6-17 17:05
可以试试如下代码。因文档较长，处理时间也会较长:：

刚测试了，可以用。感恩不尽。

我已经把代码保存下来了。以后排版佛经就用它了。

感恩你。

sylun

也可试试另一种方法，运行前提条件是得有可靠的繁简汉字对照表的纯文本文件，对照表中的统一格式为：每行均为三个字符，其中第一个为繁体字，第二个为分隔符（不限），第三个为简体字。这样就不用借助WORD自带的中文繁简转换功能而直接定位替换指定字符，速度应该快些。但感觉程序运行慢主要还是因文档太大，如果文件小些，其运行速度（每秒处理的字符数）将明显提高。
另外，这样的转换只是一一对应的关系，未考虑繁简转换的一些特殊性。如果要简转繁就更复杂了。

1. Sub test2()
   
2.     Dim fs
   
3.     Dim f
   
4.     Dim d
   
5.     Dim strText As String
   
6.     Dim aField As Field
   
7.     Dim strChinese As String
   
8.     Dim i As Long
   
9.     Dim n As Long
   
10.    
    
11.     On Error Resume Next
    
12.     Set fs = CreateObject("Scripting.FileSystemObject")
    
13.     Set f = fs.OpenTextFile("E:\汉字繁简对照.txt", 1, , -2)  '引号部分为自行指定的繁简对照表全文件名
    
14.     Set d = CreateObject("Scripting.Dictionary")
    
15.     Do While f.AtEndOfStream <> True
    
16.       strText = f.ReadLine
    
17.       d.Add Left(strText, 1), Right(strText, 1)
    
18.     Loop
    
19.     f.Close
    
20.    
    
21.     Application.ScreenUpdating = False
    
22.     For Each aField In ActiveDocument.Fields
    
23.         If aField.Type = wdFieldFormula Then
    
24.             strChinese = aField.Code.Characters.Last.Previous.Text
    
25.             If d.Exists(strChinese) = True Then
    
26.                 aField.Code.Characters.Last.Previous.Text = d(strChinese)
    
27.                 n = n + 1
    
28.             End If
    
29.             i = i + 1
    
30.         End If
    
31.     Next
    
32.     MsgBox "处理完毕。共对" & i & "个Eq域中的" & n & "个进行了中文繁简转换。"
    
33.     Application.ScreenUpdating = True
    
34. End Sub

复制代码

cuteword

这个文档太大，上面几楼的思路有问题，执行的速度和稳定性估计有问题。
我的思路是：将word文档存为xml格式(文档达到40-50M），用convertz转换也仅仅需要20秒，打开另存为doc文档即可。
整个过程估计在5分钟内。