Piny系列-1232數列研究

lhx120824 · 发表于 2010-12-18 14:21

原帖由 goodkf 于 2010-12-18 09:33 发表
用正余弦函数特性做了24个字符的
=SIN((ROW()+2)*PI()/2)+2
=COS((ROW()+1)*PI()/2)+2

数学的功底较厚，应用灵活，学习了。

piny · 发表于 2010-12-19 07:43

感谢加分鼓励

先前预设解为

27 =SIN(RADIANS(90*ROW(A3)))+2
27 =COS(RADIANS(90*ROW(A2)))+2
27 =INT(SIN(ROW(A3)*PI()/2)+2)
27 =INT(COS(ROW(A2)*PI()/2)+2)
27 =INT(COS(ROW(A2)*PI()/2)+2)
30 =ROUND(SIN(ROW(A3)*PI()/2)+2,)
30 =ROUND(COS(ROW(A2)*PI()/2)+2,)

后来认真想了一下似乎后四个取整函数略显多余

本来以为
=COS(ROW(A2)*PI()/2)

只有近似的效果所以都慎重地加了取整函数后来才发现可以去掉

目前各式最短解应为22字元为

22 =SIN(ROW(A3)*PI()/2)+2
22 =COS(ROW(A2)*PI()/2)+2

~~解答版可能尚需数日方能汇整完毕~~

piny · 发表于 2010-12-20 10:05

答案彙整 MOD變形系列僅列舉最短字元組合餘可詳系列A自行練習組合

系列A：MOD函數系列
23 =RIGHT(2+MOD(ROW(),4)%)
25 =LEFT(--(MOD(ROW(),4)&2))
26 =TEXT(MOD(ROW(),4),"0;;2")
27 =MID(2123,MOD(ROW(),4)+1,1)
29 =SUBSTITUTE(MOD(ROW(),4),0,2)
31 =CHOOSE(MOD(ROW(),4)+1,2,1,2,3)
32 =IF(MOD(ROW(),4),MOD(ROW(),4),2)
32 =INDEX({2,1,2,3},MOD(ROW(),4)+1)
32 =(GCD(ROW(),4)=4)*2+MOD(ROW(),4)
32 =(MOD(ROW(),4)=0)*2+MOD(ROW(),4)
38 =(INT(ROW()/4)=ROW()/4)*2+MOD(ROW(),4)
41 =LOOKUP(MOD(ROW(),4),{0,1,2,3},{2,1,2,3})
43 =VLOOKUP(MOD(ROW(),4),{0,2;1,1;2,2;3,3},2,)
43 =HLOOKUP(MOD(ROW(),4),{0,1,2,3;2,1,2,3},2,)
61 =(MOD(ROW(),4)=1)+OR(MOD(ROW(),4)={2,0})*2+(MOD(ROW(),4)=3)*3
74 =(MOD(ROW(),4)=1)+(MOD(ROW(),4)=2)*2+(MOD(ROW(),4)=3)*3+(MOD(ROW(),4)=0)*2

系列B：三角函數系列
22 =COS(ROW(A2)/2*PI())+2
22 =SIN(ROW(A3)/2*PI())+2
27 =SIN(RADIANS(90*ROW(A3)))+2
27 =COS(RADIANS(90*ROW(A2)))+2
35 =ACOS(COS(ROW(A4)/2*PI()))*2/PI()+1
35 =ASIN(SIN(ROW(A3)/2*PI()))*2/PI()+2

系列C：時間函數系列
29 =TEXT(HOUR(ROW()/4)/6,"0;;2")
35 =4-TEXT(MINUTE(ROW()/32)/15,"0;;2")

系列D：MOD函數變形系列【RIGHT(ROW()/4%,2)*4%】
34 =TEXT(RIGHT(ROW()/4%,2)*4%,"0;;2")

系列E：MOD函數變形系列【ROW(OFFSET(A1,-4*INT((ROW()-1)/4),))】
49 =MID(1232,ROW(OFFSET(A1,-4*INT((ROW()-1)/4),)),1)

系列F：MOD函數變形系列【ROW()-4*INT((ROW()-1)/4)】
37 =MID(1232,ROW()-4*INT((ROW()-1)/4),1)

系列G：其他系列
28 =MID(REPT(1232,9^4),ROW(),1)
50 =ISODD(ROW())+(ISEVEN(ROW())+(GCD(ROW()+1,4)=4))*2

[ 本帖最后由 piny 于 2010-12-20 14:27 编辑 ]

一剑惊心 · 发表于 2010-12-20 12:43

三角函数N年就快递还给老师了

piny · 发表于 2010-12-20 13:10

時間函數再增加三個

30 =MID(1232,MONTH(ROW()*90)/3,1)
33 =TEXT(MINUTE(ROW()/96)/15,"0;;2")
34 =TEXT(SECOND(ROW()/128)/15,"0;;2")

已更新附件

紅字公式經一劍老師測試有誤已刪

[ 本帖最后由 piny 于 2010-12-20 14:26 编辑 ]

一剑惊心 · 发表于 2010-12-20 14:25

原帖由 piny 于 2010-12-20 13:10 发表
時間函數再增加三個

30 =MID(1232,MONTH(ROW()*90)/3,1)
33 =TEXT(MINUTE(ROW()/96)/15,"0;;2")
34 =TEXT(SECOND(ROW()/128)/15,"0;;2")

已更新附件

红字公式，从第25行起出现错误，乘以90来进行季度区分，本来就很不严谨的。

piny · 发表于 2010-12-20 14:28

原帖由 一剑惊心 于 2010-12-20 14:25 发表

红字公式，从第25行起出现错误，乘以90来进行季度区分，本来就很不严谨的。

感謝告知(實際上從第23行就出錯了) 相關訊息皆已刪除謝謝

一剑惊心 · 发表于 2010-12-20 14:32

利用三角函数求出的2，似乎与手工输入的值2，进行匹配时，返回的是false，不知何故。（似乎也不存在浮点运算的原因），具体原因有待高手释疑！

piny · 发表于 2010-12-20 14:43

原帖由 一剑惊心 于 2010-12-20 14:32 发表
利用三角函数求出的2，似乎与手工输入的值2，进行匹配时，返回的是false，不知何故。（似乎也不存在浮点运算的原因），具体原因有待高手释疑！

咦沒發現這個問題 ?

一剑惊心 · 发表于 2010-12-20 14:54

40行以前不出现

		自动登录	找回密码
密码			免费注册

[讨论] Piny系列-1232數列研究