挑战! 邮件合并-合并后的以主要域名为文件名分开保存

freeclouds · 发表于 2009-1-3 00:54

看了网友们一些邮件合并的例子,但我有一个很棘手的应用：
主控文件有3页，用Word的邮件合并功能后，并要求以关键域名如“姓名+工号”的形式做为文件名，将每一条记录结果存为一个文件，而不是把所有的记录都存在一个文件。

这和朋友们提出的“[求助]如何用VBA实现每一页存为一个文件？http://club.excelhome.net/thread-246225-1-1.html ”或“[原创并分享]分页保存？ http://club.excelhome.net/viewth ... replyID=&skin=0”的问题有些区别：
1、主控文件有3页，要求以合并的记录条数（数据源为标准的EXCEL数据，结构简单）分别生成文件；
2、要求以合并的关键域名如“姓名+工号+自定义***”的形式做为文件名；

此问题很具挑战性，本人在网上查了很多有关邮件合并的贴子，但没有找到答案，但似乎又是一个很常用的邮件合并的实例问题，请教各位大虾（特别请教“守柔”版主）。谢谢！

sylun · 发表于 2009-1-3 13:07

如果对已生成的合并文档进行处理，对所提到的帖子的相关代码稍作修改应可以满足要求。
可试试以下代码，是直接从主文档运行，一次完成。可根据实际数据源自行修改相关代码定位相应字段以命名文档

Sub myMailMerge()
'主文档的类型为信函
'合并全部数据记录
'假设主文档已链接好数据源，可以进行正常的邮件合并
Dim myMerge As MailMerge, i As Integer, myname As String
Application.ScreenUpdating = False
Set myMerge = ActiveDocument.MailMerge
With myMerge.DataSource
If .Parent.State = wdMainAndDataSource Then
      .ActiveRecord = wdFirstRecord
      For i = 1 To .RecordCount
         .FirstRecord = i
         .LastRecord = i
         .Parent.Destination = wdSendToNewDocument
         '取得数据源第1个和第2个字段（合并域）的当前数据字符串，用以命名文件
         myname = .DataFields(1).Value & .DataFields(2).Value
         .ActiveRecord = wdNextRecord
         .Parent.Execute  '每次合并一个数据记录
         With ActiveDocument
            .Content.Characters.Last.Previous.Delete  '删除分节符
            .SaveAs "E:\" & myname & ".doc"  '假设生成的各文档保存于E盘根目录下
            .Close  '关闭生成的文档（已保存）
         End With
      Next
End If
End With
Application.ScreenUpdating = True
End Sub

freeclouds · 发表于 2009-1-6 15:45

非常感謝sylun，代碼執行成功！感謝指點！

kqbt · 发表于 2009-1-7 12:17

得好好学习学习这个

xxiaoa · 发表于 2009-8-16 08:41

正好需要，学习试用一下。

lhm667788 · 发表于 2009-8-16 09:45

原帖由 sylun 于 2009-1-3 13:07 发表
如果对已生成的合并文档进行处理，对所提到的帖子的相关代码稍作修改应可以满足要求。
可试试以下代码，是直接从主文档运行，一次完成。可根据实际数据源自行修改相关代码定位相应字段以命名文档

Sub myMailMerg ...

对sylun真是佩服啊！！！

hg908 · 发表于 2009-8-16 13:12

留印学习！

dsp5000 · 发表于 2009-8-16 16:22

比我的简单多了。收藏研究

berrycfz · 发表于 2010-3-17 15:49

学习了，真的非常好用！收藏学习啊！

易碎品 · 发表于 2010-3-19 12:46

我也遇到这样的问题了。

可是我才学会邮件合并等简单的操作。至于宏啦、vba啦到现在还没有入门，甚至到现在才意识到宏和vba不是一回事。
现在就算有sylun提供的宝贵的智慧结晶，我也不会用

哪个好心人来给我这个初学者点拨点拨、指点迷津？

		自动登录	找回密码
密码			免费注册

[求助] 挑战! 邮件合并-合并后的以主要域名为文件名分开保存

评分

非常感謝sylun，代碼執行成功！