请教在有空值的情况下删除重复值，统计重复值出现个数的问题

vista2086

问题描述：在A1:K1,有重复值，有空值，要直接用公式得出结果。
如：
A   B    C        D    E    F  G    H      I     J     K
2   6    空格   5    6    8   1   8      1  空格 空格

第一个问题：如何删掉重复值，然后从小到大排序?
如得出：
1   2   5  6   8

第二个问题：
如何按出现次数分组写
如出现0次有哪几个，出现1次有哪个几个？等等（取值范围1-9）
即得出：
出0次：3 4 7 9
出1次：2,5
出2次：1  6  8

第三个问题：
如何按出现次数多少按从多到少写出来，次数相同那就从小到大排序。（取值范围1-9）
然后下一行写出次数多少：
即得出：
1  6  8  2  5  3  4  7  9
2  2  2  1  1  0  0  0  0

谢谢！
详见附件：

[ 本帖最后由 vista2086 于 2010-11-3 12:42 编辑 ]

foodorwater

這個問題不太好做。
做了前面兩個問題。
當作拋磚引玉吧。請高手出招
有关删除重复值及统计重复值出现个数等.zip (6.86 KB, 下载次数: 16)

2010-11-3 10:09 上传

点击文件名下载附件

piny

問題一
A5=MIN(A1:K1)
下拉

B5=IF((A5="")+(A5=MAX(A1:K1)),"",MIN(IF($A1:$K1>A5,$A1:$K1)))
數組 右拉下拉

問題二
B6=SUBSTITUTE(SMALL(IF(COUNTIF($A$1:$K$1,ROW($1:$9))=ROW(A1)-1,ROW($1:$9),99),COLUMN(A1)),99,)
數組 右拉下拉

問題三
B12=ROUND(1/MOD(LARGE(COUNTIF($A$1:$K$1,ROW($1:$9))*100+1/ROW($1:$9),COLUMN(A1)),100),)
數組 右拉

B13=COUNTIF($A1:$K1,B12)
右拉

[ 本帖最后由 piny 于 2010-11-3 10:27 编辑 ]

vista2086

非常感谢foodorwater和piny给予帮助解答！
尤其是piny,答案总是那么完美，思路清晰良好和巧妙，
让人学习领会后获益良多。
再次向两位老师致谢！深感敬佩！

yangbin5670

=IFERROR(SMALL(IF(COUNTIF($A1:$K1,ROW($1:$100))>0,ROW($1:$100)),COLUMN(A1)),"")数组公式
=IFERROR(SMALL(IF(COUNTIF($A$1:$K$1,ROW($1:$9))=--LEFT($A6,1),ROW($1:$9)),COLUMN(A1)),"")数组公式

yangbin5670

最后一个问题
=MID(CONCATENATE($B$9,$C$9,$D$9,$E$9,$F$9,$G$9,$H$9,$B$8,$C$8,$D$8,$E$8,$F$8,$G$8,$H$8,$B$7,$C$7,$D$7,$E$7,$F$7,$G$7,$H$7,$B$6,$C$6,$D$6,$E$6,$F$6,$G$6,$H$6),COLUMN(A1),1)
=COUNTIF($A$1:$K$1,B12)

MHanys

一
=IFERROR(SMALL(IFERROR(IF(MATCH($A1:$K1,$A1:$K1,)=COLUMN($A:$K),$A1:$K1,""),""),COLUMN(A:A)),"")
二
=IFERROR(SMALL(IF(COUNTIF($A$1:$K$1,TRANSPOSE(ROW($1:$9)))=ROW()-6,TRANSPOSE(ROW($1:$9)),""),COLUMN(A:A)),"")
三
=MOD(SMALL(-COUNTIF($A$1:$K$1,TRANSPOSE(ROW($1:$9)))/1%+TRANSPOSE(ROW($1:$9)),COLUMN(A:A)),100)
=COUNTIF($A$1:$K$1,B12)