[开_124][已结束]提取首个手机号码<65楼增加难度,答案汇总在81楼>

wangg913

===================================================================

附件已经更改。
原附件中每个单元格文本中最多只有一个手机号码，
现在改为最多两个，以充分符合题意。

===================================================================


20100825 小题目.rar (41.49 KB, 下载次数: 384)

2010-8-25 08:59 上传

点击文件名下载附件

[ 本帖最后由 wshcw 于 2010-8-30 22:52 编辑 ]

wangg913

有可能存在一些地区的固定电话号码是11位，这样的也不算，附件不再改了（不好意思，开始考虑有点不周）；
=====================================================================================
比如，济南的电话，053188678867
          深圳的电话：075567896789

而这些号码 当然 也可能在  第一个手机号码  之前。

=====================================================================================
虽然也看不见，估计 wshcw  版主答对了，我的也是  58个字。

[ 本帖最后由 wangg913 于 2010-8-25 12:58 编辑 ]

夜行

个人提点小建议：

这种题目的初衷是好的，让人思考问题，解决问题。
——但有个副作用，就是让人认为，作EXCEL表的时候可以随意的填写、记录数据，整理数据的问题都交给函数等解决，这个不好。
——应该要引导大家有正确的数据管理概念。

piny

第一式：167字元（假設第一個出現11碼首字為1之數字即為所求）
=IF(SUM((MID(A2,ROW($1:70),1)="1")*(ISNUMBER(-MID(A2&"A",ROW($1:70),11)))),MID(A2,MATCH(-1,-(MID(A2,ROW($1:70),1)="1")*(ISNUMBER(-MID(A2&"A",ROW($1:70),11))),),11),"")


第二式：64字元（假設第一個出現11碼數字即為所求）
=MID(A2,MATCH(1,IF(--MID(A2&" 1e11",ROW($1:70),11)>1e10,1),),11)


第三式：107字元（假設第一個出現11碼首字為1之數字即為所求）
=MID(A2,MATCH(1,IF((--MID(A2&" 1.9e11",ROW($1:70),11)>1e10)*(--MID(A2&" 1e11",ROW($1:70),11)<2e10),1),),11)

[ 本帖最后由 piny 于 2010-8-25 10:20 编辑 ]

wshcw

没有好思路,不用TEXT的话都超百字了.

wangg913

原帖由 wshcw 于 2010-8-24 20:33 发表
没有好思路,不用TEXT的话都超百字了.

那就用text。但要取第一个手机号。

wshcw

没有好思路,不用TEXT的话都超百字了.

=MID(A2,MATCH(,0/(ISNUMBER(-MID(A2&"a"&10^10,COLUMN(1:1),11))*(--MID(A2&"a"&10^10,COLUMN(1:1),11))>=10^10),),11)
TEXT用法:


=TEXT(MAX(--TEXT(MID(A2,ROW($1:$70),11),"[>1E10]0;\0;\0;\0")),"0;;")

[ 本帖最后由 wshcw 于 2010-8-30 22:42 编辑 ]

zm0115

借鉴以前版主的思路，也凑个热闹，只是不符合大头老哥的要求，用了TEXT还要81个字符。 20100825 小题目.rar (52.15 KB, 下载次数: 54)

2010-8-25 09:40 上传

点击文件名下载附件

wshcw

没用TEXT,公式61字,但还是没达到大头的要求
=MID(A2,MATCH(,0/(--MID(A2&"A"&1/3,ROW($1:70),11)>9^10),),11)

[ 本帖最后由 wshcw 于 2010-8-30 22:46 编辑 ]

liuguansky

=MID(A2,MATCH(1&REPT("?",10),TEXT(MID(A2&" 1e10",ROW($1:$60),11),"\2@"),),11)这个应该是我目前写出来最满意的了。
字数达不到。期待答案了。

[ 本帖最后由 liuguansky 于 2010-8-26 10:12 编辑 ]