(已解决)如何在word里显示金山词霸音标字体的本来字符

wjhere

我们使用的音标大多是金山词霸音标字体Kingsoft phonetic plain 标注的。在word中把这种字体改为宋体却显示空白，在excel中改为宋体可以就可以正常显示。再复制到word里面可以用宋体显示。请看附件。

4nnPhDsm.rar (15.03 KB, 下载次数: 103)

2008-9-11 07:04 上传

点击文件名下载附件
如何在word里显示金山词霸音标字体的本来字符

[此贴子已经被作者于2008-9-11 19:27:53编辑过]

sylun

感觉与字符集有关。如下代码试图将文档中的金山字符替换为ASCII字符，看看是否需要这样的效果：
Sub KSPPtoASCII()
Application.ScreenUpdating = False
With ActiveDocument.Content.Find
    .ClearFormatting
    .Text = "[" & ChrW(61480) & "-" & ChrW(61565) & "]"
    .MatchWildcards = True
    Do While .Execute
        With .Parent
            .Font.Name = "宋体"
            .Font.NameAscii = "Times New Roman"
            .Font.NameOther = "Times New Roman"
            .Text = ChrW(AscW(.Text) + 4096)
            .Collapse wdCollapseEnd
        End With
    Loop
End With
Application.ScreenUpdating = True
End Sub

wjhere

多谢善良的sylun哥哥，正是我想要的效果

sylun

应楼主要求，对程序作了修改，运行速度估计要快些。
Sub KSPPtoASCII2()
Dim a As String, i As Byte
Application.ScreenUpdating = False
With ActiveDocument.Content.Find
    .ClearFormatting
    .Text = "[" & ChrW(61480) & "-" & ChrW(61565) & "]{1,}"
    .MatchWildcards = True
    Do While .Execute
        a = .Parent.Text
        For i = 1 To VBA.Len(a)
            a = VBA.Replace(a, Mid(a, i, 1), ChrW(AscW(Mid(a, i, 1)) + 4096))
        Next
        With .Parent
            .Text = a
            .Font.Name = "宋体"
            .Font.NameAscii = "Times New Roman"
            .Font.NameOther = "Times New Roman"
            .Collapse wdCollapseEnd
        End With
    Loop
End With
Application.ScreenUpdating = True
End Sub

wjhere

非常感谢sylun兄的热心帮助，速度果然快了许多。但也出现了新的问题，部分字符无法正确转换，请看附件。如open，home 不能正常显示。原来的可以。 gznpfmdL.rar (7.76 KB, 下载次数: 16)

2008-9-13 21:41 上传

点击文件名下载附件
(已解决)如何在word里显示金山词霸音标字体的本来字符

wjhere

可能问题是在{1,}上面，去掉后可以正确，但是速度明显慢了许多"{1,}"是什么意思？

sylun

以下代码修改了replace函数的参数，请再测试：
Sub KSPPtoASCII3()
Dim a As String, i As Byte
Application.ScreenUpdating = False
With ActiveDocument.Content.Find
    .ClearFormatting
    .Text = "[" & ChrW(61480) & "-" & ChrW(61565) & "]{1,}"
    .MatchWildcards = True
    Do While .Execute
        a = .Parent.Text
        For i = 1 To VBA.Len(a)
            a = VBA.Replace(a, Mid(a, i, 1), ChrW(AscW(Mid(a, i, 1)) + 4096), , 1)
        Next
        With .Parent
            .Text = a
            .Font.Name = "宋体"
            .Font.NameAscii = "Times New Roman"
            .Font.NameOther = "Times New Roman"
            .Collapse wdCollapseEnd
        End With
    Loop
End With
Application.ScreenUpdating = True
End Sub

"{1,}"是查找替换中的查找代码，意思为一个以上前面的字符（中括号内的字符范围），总的意思就是查找一个尽可能长的金山字体字符串

wjhere

再次感谢sylun兄的热心帮助，问题彻底解决了。我就是想把金山词霸音标转换成 ipa 14版音标，需要这个。这两天真的从sylun身上学到许多：

1、要系统学一些东西，否则像我这要浮躁的学，遇到问题没有一点思路；

2、精益求精，不厌其烦的帮助别人

3、接触到了ASCII字符，高级查找替换等新鲜的东西，并在文档循环中处理所有情况。

sylun

其实ChrW(61480)到ChrW(61565)并非金山注音字体的KSPP所有字符的范围，其后起码还有带声调的字符，其字符的Unicode字符编码起码应到61600,只是如按原规则转换，转换后字符基本为ASCII扩展字符，不一定能正常显示。

我对音标不熟悉，不知转换程序是否够用。如不够用，可试将字符范围扩大。

wjhere

已经很好用来，再次感谢sylun！