请问怎么用VBA把WORD里的图片格式一次性改为“嵌入型”

crwolf

我想把我的图片一次性用VBA改为“嵌入型”，本来想录宏，但是发现录宏的时候不让选格式为嵌入型，请高手帮忙了

谢谢

守柔

QUOTE:

以下是引用crwolf在2007-12-10 22:18:59的发言：

我想把我的图片一次性用VBA改为“嵌入型”，本来想录宏，但是发现录宏的时候不让选格式为嵌入型，请高手帮忙了

谢谢

给你一个超值的！

'* ＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋
'* Created By SHOUROU@ExcelHome 2007-12-11 5:28:26
'仅测试于System: Windows NT Word: 11.0 Language: 2052
'№ 0281^The Code CopyIn [ThisDocument-ThisDocument]^'
'* －－－－－－－－－－－－－－－－－－－－－－－－－－－－－
Option Explicit
Sub 图片版式转换()
    Dim oShape As Variant, shapeType As WdWrapType
    On Error Resume Next
    If MsgBox("Y将图片由嵌入式转为浮动式,N将图片由浮动式转为嵌入式", 68) = 6 Then
        shapeType = Val(InputBox(Prompt:="请输入图片版式:0=四周型,1=紧密型, " & vbLf & _
                                         "3=衬于文字下方,4=浮于文字上方", Default:=0))
        For Each oShape In ActiveDocument.InlineShapes
            Set oShape = oShape.ConvertToShape
            With oShape
                Select Case shapeType
                Case 0, 1
                    .WrapFormat.Type = shapeType
                Case 3
                    .WrapFormat.Type = 3
                    .ZOrder 5
                Case 4
                    .WrapFormat.Type = 3
                    .ZOrder 4
                Case Else
                    Exit Sub
                End Select
                .WrapFormat.AllowOverlap = False    '不允许重叠
            End With
        Next
    Else
        For Each oShape In ActiveDocument.Shapes
            oShape.ConvertToInlineShape
        Next
    End If
End Sub
'----------------------

crwolf

十分感谢，正是我想要的

ssq1109

奇怪！2楼守柔大侠的代码作用于下面链接中附件里的文档时，若选“Y”（即将图片由嵌入式转为浮动式）时，我刚直接测试时竟然无效！后选“N”（即将图片由浮动式转为嵌入式）时可以。于是我重新在WORD 打开此文档，选中第一个嵌入式插图（即第一个坐标图），再运行此宏，对第一、二个嵌入式图都起了作用，但对后面几个嵌入式插图又不起作用了。

百思不解！

测试于：Windows XP SP2 + Word 2003 (11.8169.8172) SP3

http://club.excelhome.net/viewthread.php?tid=284583&px=0

守柔

QUOTE:

以下是引用ssq1109在2007-12-30 18:20:12的发言：

奇怪！2楼守柔大侠的代码作用于下面链接中附件里的文档时，若选“Y”（即将图片由嵌入式转为浮动式）时，我刚直接测试时竟然无效！后选“N”（即将图片由浮动式转为嵌入式）时可以。于是我重新在WORD 打开此文档，选中第一个嵌入式插图（即第一个坐标图），再运行此宏，对第一、二个嵌入式图都起了作用，但对后面几个嵌入式插图又不起作用了。

百思不解！

测试于：Windows XP SP2 + Word 2003 (11.8169.8172) SP3

http://club.excelhome.net/viewthread.php?tid=284583&px=0

我以为这与图形本身有关系，通常情况下，嵌入式/浮动式更适合于图片而非自选图形，在此之前我记得也曾说过（不记得是哪个贴子了），请 ssq1109兄改一下代码（添加一句）再测试一下，能否通过？

  For Each oShape In ActiveDocument.InlineShapes
            oShape.Select
            Set oShape = oShape.ConvertToShape

ssq1109

QUOTE:

以下是引用守柔在2007-12-31 8:46:41的发言：

我以为这与图形本身有关系，通常情况下，嵌入式/浮动式更适合于图片而非自选图形，在此之前我记得也曾说过（不记得是哪个贴子了），请 ssq1109兄改一下代码（添加一句）再测试一下，能否通过？

  For Each oShape In ActiveDocument.InlineShapes
            oShape.Select
            Set oShape = oShape.ConvertToShape

加上选择对象一句的确可以了！非常谢谢！

tangqingfu

原帖由 守柔 于 2007-12-11 05:28 发表
QUOTE:以下是引用crwolf在2007-12-10 22:18:59的发言：我想把我的图片一次性用VBA改为“嵌入型”，本来想录宏，但是发现录宏的时候不让选格式为嵌入型，请高手帮忙了谢谢给你一个超值的！'* ＋＋＋＋＋＋＋＋＋＋＋＋ ...

  谢谢守版,收藏!

三千年不倒

太牛逼了，帮了大忙了！

liangyuhong

2楼真是太牛了，这个代码找了 N 久都不合适，叫你一次给解决了，我顶你

roses8

各位老大，我也发生了转换成浮动式插图无效的情况。请问
For Each oShape In ActiveDocument.InlineShapes
            oShape.Select
            Set oShape = oShape.ConvertToShape
这句要添加在哪行？我添加后竟然出现“控件变量已在使用”这个提示。不知是不是我添加的位置不对了。求解，谢谢。