按主要关键字和次要关键字排序问题

sxhsf

具体内容请看附件，先谢谢大神

liulang0808

楼主录制一段排序的宏，然后参考下看看

fgq5910

Sub SortDataAndDisplay()
    Dim ws As Worksheet
    Dim lastRow As Long
    Dim dataRange As Range
    Dim outputRange As Range
   
    ' 设置工作表
    Set ws = ThisWorkbook.Worksheets("Sheet1")
   
    ' 获取数据最后一行
    lastRow = ws.Cells(ws.Rows.Count, "A").End(xlUp).Row
   
    ' 检查是否有数据
    If lastRow < 2 Then
        MsgBox "没有找到数据！"
        Exit Sub
    End If
   
    ' 设置数据范围（A:D列）
    Set dataRange = ws.Range("A2:D" & lastRow)
   
    ' 设置输出范围（从F2开始）
    Set outputRange = ws.Range("F2")
   
    ' 清空之前的输出结果（F:I列）
    ws.Range("F:I").ClearContents
   
    ' 复制数据到输出区域
    dataRange.Copy outputRange
   
    ' 获取新的数据范围（F:I列）
    Dim newLastRow As Long
    newLastRow = ws.Cells(ws.Rows.Count, "F").End(xlUp).Row
    Dim sortRange As Range
    Set sortRange = ws.Range("F2:I" & newLastRow)
   
    ' 执行排序（按大队升序，再按中队升序）
    With ws.Sort
        .SortFields.Clear
        .SortFields.Add Key:=sortRange.Columns(1), Order:=xlAscending    ' 大队
        .SortFields.Add Key:=sortRange.Columns(2), Order:=xlAscending    ' 中队
        .SetRange sortRange
        .Header = xlNo
        .Apply
    End With
   
    ' 添加表头
    ws.Range("F1:I1").Value = Array("大队", "中队", "姓名", "身份证号")
   
    ' 自动调整列宽
    ws.Columns("F:I").AutoFit
   
    MsgBox "数据排序完成！结果显示在F:I列。"
End Sub

fgq5910

按第1关键词：大队，第2关键词：中队，排序，升序

sxhsf

liulang0808 发表于 2025-11-3 09:32
楼主录制一段排序的宏，然后参考下看看

我不会录制视频，截图这样，不知道表达清楚了没有，谢谢！

taller

sxhsf 发表于 2025-11-3 10:04
我不会录制视频，截图这样，不知道表达清楚了没有，谢谢！

录制宏就可以完美实现你的需求

ykcbf1100

附件供参考。。。

直接用工作表排序即可。

ykcbf1100

1. Sub ykcbf()  '//2025.11.3
   
2.     Set ws = ActiveSheet
   
3.     r = ws.Cells(ws.Rows.Count, 1).End(xlUp).Row
   
4.     Set Rng = ws.[a1].Resize(r, 4)
   
5.     Rng.Sort Key1:=Rng.Columns(1), Order1:=1, Key2:=Rng.Columns(2), Order2:=1, Header:=xlYes
   
6.     MsgBox "OK！"
   
7. End Sub
   
8. 
   

复制代码

半百

sxhsf 发表于 2025-11-3 10:04
我不会录制视频，截图这样，不知道表达清楚了没有，谢谢！

录制“宏”，不是录制“视频”，录制宏是将你的操作用代码记录下来。

yes_cn

先给数据加上“筛选”
法一：EXCEL自带的排序，此法全能、强大。
法二：先B列排升序，再A列排升序。就是你要的效果。