如何将满足条件横和竖并去重统计个数

乄.壊脾氣.爺ゞ

助公式：

1.求本年度任一天有签到人数
2.从未签到人数人公式；
条件说明：
1.满足日期C8:C507=年份F1
2.满足类型E8:E507=“团体”
3."√"&"±"&"+"这些字符只算签到算，“X”当作从未签到算，

edwin11891

一次过把3个数都求出来，预留了姓名向右随意扩展，日期向下随意扩展。

1. =LET(n,SUM(N($O6:$FZ6<>"")),S,INDIRECT("O8:"&SUBSTITUTE(ADDRESS(1,14+n,4),1,)&"1000"),Src,FILTER(S,(YEAR(C8:C1000)=F1)*(E8:E1000="团体")),a,BYCOL(Src,LAMBDA(x,SUM(IF(TRIM(x)="",0,1)))),b,SUM(N(a=0)),c,SUM(N(a<>0)),VSTACK(n,c,b))

复制代码

mykitami

R2
=COUNTA(O6:ZZ7)
R3
=SUM(BYCOL(FILTER(O8:ZZ999,(YEAR(C8:C999)=F1)*(E8:E999="团体")),LAMBDA(x,LET(a,UNIQUE(x),IF(ROWS(a)>1,1,IF(OR(a="",a="ⅹ"),0,1))))))
R4
=R2-R3
或
=SUM(BYCOL(FILTER(O8:ZZ999,(YEAR(C8:C999)=F1)*(E8:E999="团体")),LAMBDA(x,LET(a,UNIQUE(x),IF(ROWS(a)>1,0,IF(OR(a="",a="ⅹ"),1,0)))))*(O6:ZZ7<>""))

edwin11891

替楼主盘点一下，将相关人数统计出来之外，同时列出相应人员姓名。

1. =LET(n,SUM(N($O6:$FZ6<>"")),nCol,SUBSTITUTE(ADDRESS(1,14+n,4),1,),sName,INDIRECT("O6:"&nCol&"6"),S,INDIRECT("O8:"&nCol&"1000"),Src,FILTER(S,(YEAR(C8:C1000)=F1)*(E8:E1000="团体")),a,BYCOL(Src,LAMBDA(x,SUM(IF(TRIM(x)="",0,1)))),b,SUM(N(a=0)),c,SUM(N(a<>0)),sList,FILTER(sName,a<>0),uList,FILTER(sName,a=0),sFull,N(BYCOL(Src,LAMBDA(x,SUM(IF(TRIM(x)="√",1,0))))=ROWS(Src)),d,SUM(N(sFull)),FullList,IFERROR(FILTER(sName,N(sFull)),""),Res,VSTACK(HSTACK(n,c,b,d),TRANSPOSE(IFNA(VSTACK(sName,sList,uList,FullList),""))),Res)

复制代码

乄.壊脾氣.爺ゞ

edwin11891 发表于 2024-11-3 17:37
一次过把3个数都求出来，预留了姓名向右随意扩展，日期向下随意扩展。

公式最好不要溢出公式，我的是有跨好几个单元格。最好是一个单元格一个公式。谢谢~！

乄.壊脾氣.爺ゞ

edwin11891 发表于 2024-11-3 19:02
替楼主盘点一下，将相关人数统计出来之外，同时列出相应人员姓名。

这个不是我要的结果，也感谢你，我要的结果像是3楼的

edwin11891

乄.壊脾氣.爺ゞ 发表于 2024-11-3 21:23
公式最好不要溢出公式，我的是有跨好几个单元格。最好是一个单元格一个公式。谢谢~！

R2：

1. =SUM(N($O6:$FZ6<>""))

复制代码

R3：

1. =LET(n,SUM(N($O6:$FZ6<>"")),S,INDIRECT("O8:"&SUBSTITUTE(ADDRESS(1,14+n,4),1,)&"1000"),Src,FILTER(S,(YEAR(C8:C1000)=F1)*(E8:E1000="团体")),a,BYCOL(Src,LAMBDA(x,SUM(IF(TRIM(x)="",0,1)))),b,SUM(N(a=0)),c,SUM(N(a<>0)),c)

复制代码

R4：

1. =LET(n,SUM(N($O6:$FZ6<>"")),S,INDIRECT("O8:"&SUBSTITUTE(ADDRESS(1,14+n,4),1,)&"1000"),Src,FILTER(S,(YEAR(C8:C1000)=F1)*(E8:E1000="团体")),a,BYCOL(Src,LAMBDA(x,SUM(IF(TRIM(x)="",0,1)))),b,SUM(N(a=0)),c,SUM(N(a<>0)),b)

复制代码

乄.壊脾氣.爺ゞ

mykitami 发表于 2024-11-3 18:25
R2
=COUNTA(O6:ZZ7)
R3

感谢大神，
R2的公式不是我想要的，R2的公式在我原公式加一个年份条件，或另起一个带条件1和年份的条件2的统计结果
R3和R4的公式可以，没有问题，但套用我正式表内，显示#VALUE!，我把你的公式年份的条件删除（(YEAR($C$8:$C$507)=$D$1)）就正常，我的正式表内的C单元格日期是用公式套用过来的，可能是我的C单元格的日期格式问题，非常感放您~！

乄.壊脾氣.爺ゞ

edwin11891 发表于 2024-11-3 21:27
R2：

R3：

这次的公式是我想要的，同样，我C单元格日期是公式套用过来的，可能是日期的格式问题，套用我正式表内就显示错误。

mykitami

乄.壊脾氣.爺ゞ 发表于 2024-11-3 21:33
感谢大神，
R2的公式不是我想要的，R2的公式在我原公式加一个年份条件，或另起一个带条件1和年份的条件2 ...

R2的总人数与年份有什么关系？
如果有人总是空着不签到，他属于那个年份呢？是不是也要算在总人数中