查询教师任教科目依次填入

zhaoxuie · 发表于 2024-9-30 09:47

求大神帮忙，设置函数公式，查询教师任教科目依次填入

1786024734 · 发表于 2024-9-30 09:55

=INDEX($G:$G,SMALL(IF($F$1:$F$83=$L5,ROW($1:$83),4^8),COLUMN(A1)))&""

复制代码

右、下拉

leepoison · 发表于 2024-9-30 10:02

=TRANSPOSE(FILTER(G:G,F:F=L5))

zjyxp · 发表于 2024-9-30 10:05

=TOROW(UNIQUE(FILTER($G$2:$G$83,$F$2:$F$83=$L5)))

袁勇 · 发表于 2024-9-30 10:13

低版本，非数组。
=LOOKUP(COLUMN(A1)-1,COUNTIF(OFFSET($F$1,,,ROW($1:$100)),$L5),$G$2:$G$101)&""
=INDEX($G:$G,AGGREGATE(15,6,ROW($2:$100)/1%%^($F$2:$F$100<>$L5),COLUMN(A1)))&""
...

你是那块小饼干 · 发表于 2024-9-30 10:27

=UNIQUE(TRANSPOSE(FILTER($G$2:$G$83,$F$2:$F$83=$L5,"")),TRUE)

zhaoxuie · 发表于 2024-9-30 10:30

1786024734 发表于 2024-9-30 09:55
右、下拉

请问一下，这段是什么意思？

SMALL(IF($F$1:$F$473=$L5,ROW($1:$473),4^8),COLUMN(A1))

1786024734 · 发表于 2024-9-30 10:56

zhaoxuie 发表于 2024-9-30 10:30
请问一下，这段是什么意思？
SMALL(IF($F$1:$F$473=$L5,ROW($1:$473),4^8),COLUMN(A1))

一对多条件查询（INDEX+SMALL+IF+ROW）
https://club.excelhome.net/thread-1366724-1-1.html
(出处: ExcelHome技术论坛)

waternew · 发表于 2024-9-30 11:07

=IFERROR(INDEX(UNIQUE(FILTER($F:$G,$F:$F=$L5)),COLUMN(A:A),2),"")

mykitami · 发表于 2024-9-30 11:16

M5公式
=TOROW(UNIQUE(FILTER($G$2:$G$83,$F$2:$F$83=$L5)))

		自动登录	找回密码
密码			免费注册

[求助] 查询教师任教科目依次填入