如何自动编号？

lzy0451 · 发表于 2024-3-11 16:05

能根据分类自动，在毛坯批号内自动连续编号，我写的公式表格一直在计算中..................，使文件变的非常大。有没有简单的方法。
我写=IFS(A3="库房",A3&COUNTIF($A$2:A3,A3)+4341,A3="汇磁生产",A3&COUNTIF($A$2:A3,A3)+5259,A3="外购",A3&COUNTIF($A$2:A3,A3))

请优化

cyh3230 · 发表于 2024-3-11 16:30

A2&VLOOKUP(A2,{"外购",1;"库房",4341;"汇磁生产",5259},2,0)+COUNTIF($A$2:A2,A2)
这个, 我感觉稍微快一点

leepoison · 发表于 2024-3-11 16:32

=A3 & (COUNTIF($A$2:A3, A3) + IF(A3="库房", 4341, IF(A3="汇磁生产", 5259, 0)))

mykitami · 发表于 2024-3-11 16:35

C7135公式
=IF(A7135="","",A7135&IFERROR(--SUBSTITUTE(TAKE(FILTER($C$2:C7134,$A$2:A7134=A7135),-1),A7135,),0)+1)

混沌音符 · 发表于 2024-3-11 17:00

有个不成熟的建议，插3列去辅助计数，一定不卡

qydn · 发表于 2024-3-11 20:52

试试这个试试这个

boyuanoffice · 发表于 2024-3-11 22:47

本帖最后由 boyuanoffice 于 2024-3-12 08:59 编辑

C2下拉公式，这个快的多。

=A2&MID(XLOOKUP(A2&"*",$C$1:C1,$C$1:C1,A2&SWITCH(A2,"库房",4341,"汇磁生产",5259,0),2,-1),LEN(A2)+1,9)+1

复制代码

如果不支持XLOOKUP，可以用以下这个，不过稍慢一些

=A2&MID(IFERROR(LOOKUP(9,FIND(A2,$C$1:C1),$C$1:C1),A2&SWITCH(A2,"库房",4341,"汇磁生产",5259,0)),LEN(A2)+1,9)+1

复制代码

lzy0451 · 发表于 2024-3-12 15:08

qydn 发表于 2024-3-11 20:52
试试这个试试这个

WPS不能使用

确实很快

lzy0451 · 发表于 2024-3-12 15:26

boyuanoffice 发表于 2024-3-11 22:47
C2下拉公式，这个快的多。

如果不支持XLOOKUP，可以用以下这个，不过稍慢一些

$C$1:C1,使用两次，我没有太看懂

		自动登录	找回密码
密码			免费注册

[求助] 如何自动编号？