关于字符转数字规范格式的问题。

gbgbxgb

写了一个使用正则的自定义函数供参考：
Function my_replace(rng As Range) As Double
    Dim reg As Object, theStr$
    '
    theStr = rng
    Set reg = CreateObject("VBScript.RegExp")
    With reg
        .Pattern = "^(?=.*\.)(?=.*,)"
        If .test(theStr) Then
            theStr = Replace(theStr, ".", ",")
            .Pattern = ",(?=[^,]+$)"
            theStr = .Replace(theStr, ".")
        End If
        .Pattern = "-$"
        If .test(theStr) Then theStr = "-" & .Replace(theStr, "")
    End With
    my_replace = theStr
    Set reg = Nothing
End Function

ovxyz

我是公司的win10，提示这样的，我搜了一下，能搜到文件，但无法运行，用dos命令也无法运行，奇怪。
是不是也成vba调用reguar也是一样的？

ovxyz

gbgbxgb 发表于 2023-2-24 15:44
写了一个使用正则的自定义函数供参考：
Function my_replace(rng As Range) As Double
    Dim reg As Ob ...

感谢兄弟，运行没有问题。

LIUZHU

既然是WPS，那就给一个WPS的解决方案好了，JSA写的，用JS宏运行

LIUZHU

附件，请测试

LIUZHU

运行结果如下

qdtzq

数字定长15位，替换、重组都能解决

准提部林

Function CheckNum(X$)
Dim Y$, T$
If InStr(X, "-") Then Y = "-"
X = Replace(Replace(X, "-", ""), ".", ",")
T = Right(X, 3)
If T Like ",##" Then X = Replace(X & "/", T & "/", "." & Mid(T, 2))
CheckNum = Format(Y & X, "#,##0.00")
End Function

gbgbxgb

ovxyz 发表于 2023-2-24 16:29
感谢兄弟，运行没有问题。

那个自定义函数问题很大。
你大意了，没认真与源数据比较。
我花时间写了代码，你把待处理的“原始文件.txt”放在桌面上，然后运行下列代码试试：
Sub ljljlj()
    Dim theStr$, my_TextFileFullName$, a As Variant, i&, j&
    Dim theMatches As Object, theMatch As Variant, reg As Object
    '
    my_TextFileFullName = CreateObject("WScript.Shell").SpecialFolders("Desktop") & "\原始文件.txt"
    With CreateObject("ADODB.Stream")
        .Type = 2
        .Mode = 3
        .Open
        .LoadFromFile my_TextFileFullName
        .Charset = "UTF-8"
        .Position = 2
        theStr = .ReadText
        .Close
    End With
    Set reg = CreateObject("VBScript.RegExp")
    With reg
        .Global = True
        .MultiLine = True
        .Pattern = "^([^\r\n]*)(\r?\n|\r)?"
        Set theMatches = .Execute(theStr)
    End With
    '
    reg.Pattern = "\s"
    With Sheet1
        For Each theMatch In theMatches
            theStr = theMatch.submatches(0)
            If reg.test(theStr) Then theStr = reg.Replace(theStr, "")
            '
            If InStr(1, theStr, "|") > 0 Then
                a = Split(theStr, "|")
                If Left(a(0), 1) <> "-" Then
                    i = i + 1
                    For j = 0 To UBound(a)
                        theStr = a(j)
                        If InStr(1, theStr, ",") > 0 Or InStr(1, theStr, ".") > 0 Then theStr = my_replace(theStr)
                        .Cells(i, j + 1) = theStr
                    Next j
                End If
            End If
        Next theMatch
        .Cells(1).CurrentRegion.Columns.AutoFit
    End With
    Set reg = Nothing
End Sub

Function my_replace(theStr$) As Double
    Dim reg As Object
    '
    theStr = Replace(theStr, ".", ",")
    Set reg = CreateObject("VBScript.RegExp")
    With reg
        .Global = True
        .Pattern = "[^\d\.,-]"
        If .test(theStr) Then theStr = .Replace(theStr, "")
        .Pattern = "-$"
        If .test(theStr) Then theStr = "-" & .Replace(theStr, "")
        .Pattern = ",(?=\d{2}[^\d]*$)"
        If .test(theStr) Then theStr = .Replace(theStr, ".")
    End With
    my_replace = theStr
    Set reg = Nothing
End Function

LIUZHU

gbgbxgb 发表于 2023-2-25 01:30
那个自定义函数问题很大。
你大意了，没认真与源数据比较。
我花时间写了代码，你把待处理的“原始文件 ...

代码太长了