EXCEL另存为PDF后如何关闭PDF文件

morpheus126

大家好，请教如下问题：
使用另存为PDF后，PDF会自动打开激活，请问此时应该如何关闭这个PDF文档
感谢感谢！！

1. ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, _
   
2.     Filename:=sFull, _
   
3.     Quality:=xlQualityStandard, _
   
4.     IncludeDocProperties:=True, _
   
5.     IgnorePrintAreas:=False, _
   
6.     OpenAfterPublish:=True

复制代码

游乐缘

OpenAfterPublish:=True改成OpenAfterPublish:=False试试

morpheus126

游乐缘 发表于 2022-1-11 20:43
OpenAfterPublish:=True改成OpenAfterPublish:=False试试

哇塞，可行，非常感谢！

但是我还是想追问一下，假设不通过此属性，而是指定关闭某个PDF或者其他文档（当然不是EXCEL），应该用什么代码，谢谢！

游乐缘

morpheus126 发表于 2022-1-11 21:04
哇塞，可行，非常感谢！

但是我还是想追问一下，假设不通过此属性，而是指定关闭某个PDF或者其他文档 ...

使用这句shell可以结束Adobe Reader任务，也就是关闭所有PDF文件。
Call Shell("TaskKill /F /IM AcroRd32.exe", vbHide)

如果是其他程序，替换语句中的程序名称AcroRd32.exe即可。

morpheus126

游乐缘 发表于 2022-1-11 21:39
使用这句shell可以结束Adobe Reader任务，也就是关闭所有PDF文件。
Call Shell("TaskKill /F /IM AcroRd ...

shell 我也找过这一句，但是……假设人家不是用Adobe的，是不是这个就无效了

游乐缘

morpheus126 发表于 2022-1-11 21:45
shell 我也找过这一句，但是……假设人家不是用Adobe的，是不是这个就无效了

可以试试用API，FindWindow找到指定标题的窗口，然后关闭窗口

mafect

进来学习一下

游乐缘

游乐缘 发表于 2022-1-12 06:45
可以试试用API，FindWindow找到指定标题的窗口，然后关闭窗口

一番搜索+编辑+测试之后，API关闭窗口的答案来了。用到的API函数有：FindWindow、GetWindowText、GetWindowTextLength、GetWindow、PostMessage
通过Function GetHandleFromPartialCaption获取标题中包含指定内容(例：test.pdf)的窗口句柄。
如果发现符合条件的窗口，则使用PostMessage关闭此窗口。

1. Option Explicit
   
2. 
   
3. Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" ( _
   
4.     ByVal lpClassName As String, _
   
5.     ByVal lpWindowName As String) As Long
   
6. Private Declare Function GetWindowText Lib "user32" Alias "GetWindowTextA" ( _
   
7.     ByVal hWnd As Long, _
   
8.     ByVal lpString As String, _
   
9.     ByVal cch As Long) As Long
   
10. Private Declare Function GetWindowTextLength Lib "user32" Alias "GetWindowTextLengthA" ( _
    
11.     ByVal hWnd As Long) As Long
    
12. Private Declare Function GetWindow Lib "user32" ( _
    
13.     ByVal hWnd As Long, ByVal wCmd As Long) As Long
    
14. Private Declare Function PostMessage Lib "user32" Alias "PostMessageA" ( _
    
15.     ByVal hWnd As Long, _
    
16.     ByVal wMsg As Long, _
    
17.     ByVal wParam As Long, lParam As Any) As Long
    
18. 
    
19. Const WM_CLOSE = &H10
    
20. Const GW_HWNDNEXT = 2
    
21. Public lhWndP As Long
    
22. 
    
23. Sub ClosePDFwindow()
    
24. 
    
25.     Dim strCaption As String
    
26.     strCaption = "test.pdf"
    
27.     If GetHandleFromPartialCaption(lhWndP, strCaption) = True Then
    
28.         PostMessage lhWndP, WM_CLOSE, 0&, 0&
    
29.     End If
    
30. 
    
31. End Sub
    
32. 
    
33. Function GetHandleFromPartialCaption(ByRef lWnd As Long, ByVal sCaption As String) As Boolean
    
34. 
    
35.     Dim sStr As String
    
36.     GetHandleFromPartialCaption = False
    
37.     lhWndP = FindWindow(vbNullString, vbNullString) 'PARENT WINDOW
    
38.     Do While lhWndP <> 0
    
39.         sStr = String(GetWindowTextLength(lhWndP) + 1, Chr$(0))
    
40.         GetWindowText lhWndP, sStr, Len(sStr)
    
41.         sStr = Left$(sStr, Len(sStr) - 1)
    
42.         If InStr(1, sStr, sCaption) > 0 Then
    
43.             GetHandleFromPartialCaption = True
    
44.             lWnd = lhWndP
    
45.             Exit Do
    
46.         End If
    
47.         lhWndP = GetWindow(lhWndP, GW_HWNDNEXT)
    
48.     Loop
    
49. 
    
50. End Function

复制代码

游乐缘

游乐缘 发表于 2022-1-12 10:05
一番搜索+编辑+测试之后，API关闭窗口的答案来了。用到的API函数有：FindWindow、GetWindowText、GetWind ...

注：此方法不限于关闭pdf窗口，其他程序窗口也可以关闭。

月关

简单点，可以插一句  Application.SendKeys "%{F4}"
或者  CreateObject("WSCript.Shell").SendKeys "%{F4}"
没怎么试过，但是一般程序应该都是可以关闭掉的