如何多条件去重复项和空值

18804205972 · 发表于 2021-5-12 22:01

根据A列的条件把I列不重复的内容显示出来,求解

sandays · 发表于 2021-5-12 22:32

=UNIQUE(FILTER(I5:I13,MMULT((A5:A13=TRANSPOSE(K6:K7))*(I5:I13<>""),{1;1})))

18804205972 · 发表于 2021-5-12 22:46

sandays 发表于 2021-5-12 22:32
=UNIQUE(FILTER(I5:I13,MMULT((A5:A13=TRANSPOSE(K6:K7))*(I5:I13""),{1;1})))

大佬,FILTER能用其他函数实现嘛,不是365用不了吧

2datou · 发表于 2021-5-12 23:19

18804205972 发表于 2021-5-12 22:46
大佬,FILTER能用其他函数实现嘛,不是365用不了吧

=UNIQUE(FILTER(I5:I13,(A5:A13=K6)*(I5:I13<>"")+(A5:A13=K7)*(I5:I13<>"")))

复制代码

filter2019也能用吧，不过得加入预览者体验计划

jians0529 · 发表于 2021-5-13 08:34

=IFERROR(INDEX(I:I,AGGREGATE(15,6,IF((MATCH($I$5:$I$13,$I$5:$I$13,)*($F$5:$F$13<>""))=ROW($1:$9),ROW($5:$13)),ROW(A1))),"")
数组公式下拉

18804205972 · 发表于 2021-5-13 09:58

jians0529 发表于 2021-5-13 08:34
=IFERROR(INDEX(I:I,AGGREGATE(15,6,IF((MATCH($I$5:$I$13,$I$5:$I$13,)*($F$5:$F$13""))=ROW($1:$9),ROW ...

产生金额不一定能报销,只有打车和地铁可以报销,所以不能用金额判断,我修改一下,换了判断条件,请指正
=IFERROR(INDEX(I:I,AGGREGATE(15,6,IF((MATCH($I$5:$I$13,$I$5:$I$13,)*($A$5:$A$13<>"自驾")*($A$5:$A$13<>"公交"))=ROW($1:$9),ROW($5:$13)),ROW(A1))),"")

jians0529 · 发表于 2021-5-13 10:08

18804205972 发表于 2021-5-13 09:58
产生金额不一定能报销,只有打车和地铁可以报销,所以不能用金额判断,我修改一下,换了判断条件,请指正
=IF ...

这样可以呀！那没金额对应项也要列出来？如果没金额的不列主再加个金额<>“”的条件

niko88819 · 发表于 2021-5-13 14:01

本帖最后由 niko88819 于 2021-5-13 14:03 编辑

数组公式

=INDEX(I:I,SMALL(IF(($A$5:$A$13=TRANSPOSE($K$6:$K$7))*--MATCH($I$5:$I$13&"",$I$5:$I$13&"",)=ROW($1:$9),ROW($5:$13),4^8),ROW(A1)))&""

复制代码

袁勇 · 发表于 2021-5-13 14:51

非数组：

=LOOKUP(1,0/FREQUENCY(1,COUNTIF(K$6:K$7,A$5:A$13)*(I$5:I$13<>"")*(COUNTIF(N$4:N4,I$5:I$13)=0)),I$5:I$13)&""

复制代码

		自动登录	找回密码
密码			免费注册

[求助] 如何多条件去重复项和空值

评分

评分

最新热点 /1