如何通过VBA提取指定表格中不重复的数据进行填充

小相公

各位老师，求教，如何通过VBA提取指定表格中不重复的数据进行填充

1、将“表1”中A列的数据填写到“总表”A列的空单元格往下填充；

2、并且不与A列已经有的数据重复；

不更改“总表”中原有的数据

老骥705664849

Sub tets()
Dim d As Object
Set d = CreateObject("scripting.dictionary")
With Sheets("表1")
    r = .Cells(Rows.Count, 1).End(xlUp).Row
    ar = .Range("a1:a" & r)
    m = UBound(ar)
End With
With Sheets("总表")
    rs = .Cells(Rows.Count, 1).End(xlUp).Row
    br = .Range("a1:a" & rs + m)
    For i = 2 To UBound(br)
        If Trim(br(i, 1)) <> "" Then
            d(Trim(br(i, 1))) = ""
        End If
    Next i
    n = rs
    For i = 2 To UBound(ar)
        If Trim(ar(i, 1)) <> "" Then
            If Not d.exists(Trim(ar(i, 1))) Then
                n = n + 1
                br(n, 1) = ar(i, 1)
            End If
        End If
    Next i
    .Cells(1, 1).Resize(n, 1) = br
End With
End Sub

老骥705664849

一个数组+字典的典型案例，

小相公

老骥705664849 发表于 2020-7-10 14:30
Sub tets()
Dim d As Object
Set d = CreateObject("scripting.dictionary")

老师你太厉害了，谢谢
引用的数字能设置为文本格式吗？VBA小白能麻烦您再帮忙补充一下吗，万分感谢

小相公

老骥705664849 发表于 2020-7-10 14:31
一个数组+字典的典型案例，

小白，不懂

老骥705664849

小相公 发表于 2020-7-10 14:58
老师你太厉害了，谢谢
引用的数字能设置为文本格式吗？VBA小白能麻烦您再帮忙补充一下吗，万分感谢

实现手工设置一下单元格格式不就行了吗，不是什么都要代码来帮你做的

小相公

老骥705664849 发表于 2020-7-10 15:08
实现手工设置一下单元格格式不就行了吗，不是什么都要代码来帮你做的

好的，明白了，谢谢

gwjkkkkk

Option Explicit
Sub TEST()
    Dim ar, i&, dic As Object
   
    Set dic = CreateObject("Scripting.Dictionary")
   
    ar = [A1].CurrentRegion
    For i = 2 To UBound(ar): dic(ar(i, 1)) = "": Next
    ar = Sheets(2).[A1].CurrentRegion
    For i = 2 To UBound(ar): dic(ar(i, 1)) = "": Next
   
    [A1].CurrentRegion.Offset(1).Clear
    Columns(1).NumberFormatLocal = "@"
    [A2].Resize(dic.Count) = Application.Transpose(dic.keys)
    Set dic = Nothing
    Beep
End Sub

gwjkkkkk

参与一下。。。

忙昏头

老师你太厉害了，学习了