word试卷试题与答案分开

zhouguangcai · 发表于 2016-8-28 13:19

请问大侠：如何利用这张试卷（如试卷样本（前）样式），将试卷的试题与答案按照题号分别显示在同一个文档中（如试卷样本（后）显示那样），该如何操作才能实现啊？求详细解答，谢谢先！【查找和替换，还是VBA或其他方法】

duquancai · 发表于 2016-8-28 18:22

本帖最后由 duquancai 于 2016-8-29 00:24 编辑

Private Sub CommandButton1_Click()
Dim S$, mt, mh, Orng As Range, trng As Range
Dim Arg As Range, m%, i%, j%
Set Arg = ActiveDocument.Content
Selection.EndKey wdStory
Selection.Text = Chr(13) & "--------------中考数学答案--------------" & Chr(13)
Selection.Collapse wdCollapseEnd
With CreateObject("VBScript.Regexp")
.Global = True: .MultiLine = True
.Pattern = "^([一二三四]+、[^\r]+\r)(?:(?!^[一二三四]+、[^\r]+\r).)+"
For Each mt In .Execute(Arg)
S = mt.submatches(0)
Selection.Text = S
Selection.Collapse wdCollapseEnd
i = mt.FirstIndex: j = mt.Length
Set Orng = ActiveDocument.Range(i, i + j)
.Pattern = "^【分析】.+?【答案】(?:(?!^【点评】).)+"
For Each mh In .Execute(Orng)
m = m + 1
i = mh.FirstIndex: j = mh.Length
Set trng = ActiveDocument.Range(Orng.Start + i, Orng.Start + i + j)
trng.Copy
Selection.Text = m & "."
Selection.Collapse wdCollapseEnd
Selection.Paste
Next
Next
End With
With ActiveDocument.Content.Find
.Text = "【考点】*【分析】*【解答】*【答案】*【点评】[!^13]@^13"
.Execute
.Replacement.Text = ""
.MatchWildcards = True
.Execute Replace:=wdReplaceAll
End With
End Sub

复制代码

duquancai · 发表于 2016-8-29 00:20

请下载附件，打开Word文档，点击按钮，OK！

zhouguangcai · 发表于 2016-8-29 08:13

duquancai 发表于 2016-8-29 00:20
请下载附件，打开Word文档，点击按钮，OK！

很好，比我想象的还好，谢谢你，大师。只是我是一个笨虾，不会操作，在我复制代码进入宏时，却显示缺少end sub，怎么回事啊？能将详细操作讲解吗？再次表示谢谢。

duquancai · 发表于 2016-8-29 09:44

zhouguangcai 发表于 2016-8-29 08:13
很好，比我想象的还好，谢谢你，大师。只是我是一个笨虾，不会操作，在我复制代码进入宏时，却显示缺少en ...

你只需要把第一句随便改一下，Private Sub CommandButton1_Click()
比如改为：Sub shiyishi()

zhouguangcai · 发表于 2016-8-29 12:16

duquancai 发表于 2016-8-29 09:44
你只需要把第一句随便改一下，Private Sub CommandButton1_Click()
比如改为：Sub shiyishi()

我真的太笨了，从来没使用过word宏操作过文档，真不懂啊。在使用中出现了什么二义名Private Sub CommandButton1_Click()咋回事？如果不用执行宏按钮（怕打印出，也影响美观），而用宏直接运行不行吗？能截图讲解使用方法吗？谢谢你，你的方法真的太棒了，想学想会用，恳请一教

KGB的愤怒 · 发表于 2016-8-29 12:21

试卷样本（前），准备两份。在执行查找替换时，它俩都要勾上使用通配符。

获取试题的这一份：
查找栏：【考点】*【点评】*^13
替换栏：留空

获取答案的这一份：
查找栏：([0-9]．)*(【分析】*)(【点评】*^13)
替换栏：\1\2

zhouguangcai · 发表于 2016-8-29 15:45

KGB的愤怒发表于 2016-8-29 12:21
试卷样本（前），准备两份。在执行查找替换时，它俩都要勾上使用通配符。

获取试题的这一份：

不错很好！你很棒！谢谢你！学习了。

zhouguangcai · 发表于 2016-8-30 11:39

zhouguangcai 发表于 2016-8-29 12:16
我真的太笨了，从来没使用过word宏操作过文档，真不懂啊。在使用中出现了什么二义名Private Sub CommandB ...

很想学习，教一哈学生呗

大雨治水 · 发表于 2016-12-31 14:26

我依葫芦画瓢，加了一点把标题和题型加黑的内容！

Sub 先复制备份文档()
Selection.WholeStory 'CTR+A
Selection.Copy
Documents.Add DocumentType:=wdNewBlankDocument
Selection.PasteAndFormat (wdPasteDefault)
ChangeFileOpenDirectory ThisDocument.Path & ""
ActiveDocument.SaveAs FileName:="试卷与答案(已分开).doc"
Call 试题与答案分开
MsgBox "已经将试卷与答案分开，请保存当前文档！"
Selection.HomeKey Unit:=wdStory ''跳到文首
End Sub
Sub 试题与答案分开()
Dim S$, mt, mh, Orng As Range, trng As Range
Dim Arg As Range, m%, i%, j%
Set Arg = ActiveDocument.Content
Selection.EndKey wdStory
Selection.InsertBreak Type:=wdPageBreak ''插入分页符
Selection.Text = "------------------中考数学答案------------------" & Chr(13) & Chr(13)
Selection.Font.Size = 16
Selection.ParagraphFormat.Alignment = wdAlignParagraphCenter
Selection.Font.Name = "黑体"
Selection.Collapse wdCollapseEnd ''跳到下一行行首
With CreateObject("VBScript.Regexp")
.Global = True: .MultiLine = True
.Pattern = "^([一二三四]+、[^\r]+\r)(?:(?!^[一二三四]+、[^\r]+\r).)+"
For Each mt In .Execute(Arg)
S = mt.submatches(0)
Selection.Text = S
Selection.Font.Size = 12
Selection.Font.Name = "黑体"
Selection.Collapse wdCollapseEnd
i = mt.FirstIndex: j = mt.Length
Set Orng = ActiveDocument.Range(i, i + j)
.Pattern = "^【分析】.+?【答案】(?:(?!^【点评】).)+"
For Each mh In .Execute(Orng)
m = m + 1
i = mh.FirstIndex: j = mh.Length
Set trng = ActiveDocument.Range(Orng.Start + i, Orng.Start + i + j)
trng.Copy
Selection.Text = m & "."
Selection.Collapse wdCollapseEnd
Selection.Paste
Next
Next
End With
With ActiveDocument.Content.Find
.Text = "【考点】*【分析】*【解答】*【答案】*【点评】[!^13]@^13"
.Execute
.Replacement.Text = ""
.MatchWildcards = True
.Execute Replace:=wdReplaceAll
End With
End Sub

复制代码

		自动登录	找回密码
密码			免费注册

[求助] word试卷试题与答案分开

评分

评分