如何用VBA将邮件内容HTML化

civl · 发表于 2012-8-9 22:43

Sub 发邮件()
Dim OutlookApp As Outlook.Application
Dim MItem As Outlook.MailItem
Dim EmailAddr As String
Dim subj As String
Dim Msg As String
Set OutlookApp = Outlook.Application
EmailAddr = "test@163.com"
subj = "我是主题"
Msg = "您好" & vbCrLf & vbCrLf
Msg = Msg & "我的正文如下：" & vbCrLf & vbCrLf
Msg = Msg & "我的签名" & vbCrLf
MsgBox Msg
Set MItem = OutlookApp.createItem(olMailItem)
With MItem
.To = EmailAddr
.Subject = subj
.Body = Msg
.Save
End With
End Sub

复制代码

我想在正文中插入一个2列4行的表格，并且第一行文字是粗体，但不太熟悉HTML方面的语句，请问老师我该如何进阶？Outlook中可以用HTML的语言吗？有例更好。谢谢！

sunya_0529 · 发表于 2012-8-10 11:41

告诉你个小技巧，如果对HTML语言不是很熟悉的话，可以在Word或者Excel里把要做的东西做好后保存成“HTML”文件格式，然后使用记事本打开这个文件，就可以得到HTML代码了。不过通常由Office软件创建的见面文件，里面包含了很多重复的CSS代码，所以在Word里操作时尽量少使用格式，这样代码不会太冗余。

得到这些代码后，可以使用一个变量，如“Msg”来将他们保存起来，然后在“MItem"对象里使用”.HTMLBody＝Msg"就可以了。

civl · 发表于 2012-8-15 07:26

本帖最后由 civl 于 2012-8-15 07:28 编辑

Function GetBoiler(ByVal sFile As String) As String
'作者：Dick Kusleika
Dim fso As Object
Dim ts As Object
Set fso = CreateObject("Scripting.FileSystemObject")
Set ts = fso.GetFile(sFile).OpenAsTextStream(1, -2)
GetBoiler = ts.readall
ts.Close
End Function
Sub Mail_Outlook_With_Signature_Html()
' 别忘记在模块中加上GetBoiler函数
' 可以在Office 2000-2010版本中通用
Dim OutApp As Object
Dim OutMail As Object
Dim strbody As String
Dim SigString As String
Dim Signature As String
Set OutApp = CreateObject("Outlook.Application")
Set OutMail = OutApp.CreateItem(0)
strbody = "<H3>尊敬的XXX</H3>" & _
"我是正文. " & _
"所以你看见了我,说明宏正确地运行了. " & _
"<A HREF=""http://club.excelhome.net/forum.php"">ExcelHome</A>" & _
" Regards"
'建立新邮件.htm（以html格式保存的附件），请查看自己系统中签名是什么，再替换“建立新邮件”这五个字。
'签名保存在windows的每个用户appdata目录下的文件，每个人都不同。具体是
'Win7中Outlook的签名位置
'C:\用户\你的大名\AppData\Roaming\Microsoft\Signatures
'WinXP中Outlook的签名位置
'C:\Documents and Settings\你的大名\Application Data\Microsoft\Signatures
'获取方式是使用Environ函数，并指定appdata作为需要搜索的系统文件夹
SigString = Environ("appdata") & _
"\Microsoft\Signatures\建立新邮件.htm"
'但是，如果签名中有图片，必须做以下改动才能使图片不显示大叉，必须将“建立新邮件.html”文件中的图片地址改为绝对地址
'因为Oultlook保存签名时，html文件是使用如2行引用了相对地址作为图片超链接的
'src = "建立新邮件_files/image001.png
'src = "建立新邮件_files/image001.jpg
'你可以使用记事本打开“建立新邮件.html”，关键字为你的图片文件名称，"/"前的内容要替换为""，即绝对地址是
'Win7用户
'src = "C:\用户\你的大名\AppData\Roaming\Microsoft\Signatures\建立新邮件_files\image001.png
'src = "C:\用户\你的大名\AppData\Roaming\Microsoft\Signatures\建立新邮件_files\建立新邮件_files/image001.jpg
'WinXP用户
'src = "C:\Documents and Settings\你的大名\Application Data\Microsoft\Signatures\建立新邮件_files\image001.png
'src = "C:\Documents and Settings\你的大名\Application Data\Microsoft\Signatures\建立新邮件_files\建立新邮件_files/image001.jpg
'就能正常地在签名中显示图片了
'调用GetBoiler函数对Signature变量进行赋值
If Dir(SigString) <> "" Then
Signature = GetBoiler(SigString)
Else
Signature = ""
End If
On Error Resume Next
With OutMail
.To = "Test@office.com;billgates@microsoft.com" '主送
.CC = "" '抄送
.BCC = "" '密送
.Subject = "我是主题" '主题
.HTMLBody = strbody & " " & Signature 'html格式正文
.display '在Outlook界面显示该封待发送邮件
'.Attachments.Add ("C:\test.txt") '附件
'.save '保存到草稿箱
'.send '直接发送
End With
On Error GoTo 0
Set OutMail = Nothing
Set OutApp = Nothing
End Sub

复制代码

我做好了，能正常发送html格式的邮件，包括签名。
签名图片要自己在电脑里将相对引用改为绝对引用，才能正确显示

testEmail.rar (17.25 KB, 下载次数: 685)
参考的代码地址：http://www.rondebruin.nl/mail/folder3/signature.htm
作者是Dick Kusleika，我作了少许翻译

Bruce_xu · 发表于 2012-11-13 13:49

Mark.

tlaan · 发表于 2012-11-17 14:38

好用，受用

andrewyang · 发表于 2014-7-12 20:05

sunya_0529 发表于 2012-8-10 11:41
告诉你个小技巧，如果对HTML语言不是很熟悉的话，可以在Word或者Excel里把要做的东西做好后保存成“HTML”文 ...

谢谢高人指点这个方法找了好久研究中

andrewyang · 发表于 2014-7-12 20:14

civl 发表于 2012-8-15 07:26
我做好了，能正常发送html格式的邮件，包括签名。
签名图片要自己在电脑里将相对引用改为绝对引用，才能 ...

其中的“签名”效果是怎样的？可以放到最后么？
即如下结果按照下面的顺序

HTMLBody

Attachments

Signature

cccc5900 · 发表于 2015-1-24 17:10

civl 发表于 2012-8-15 07:26
我做好了，能正常发送html格式的邮件，包括签名。
签名图片要自己在电脑里将相对引用改为绝对引用，才能 ...

你好，

我按你说的，用TXT打开HTML，并改了路径。
'src = "C:\用户\你的大名\AppData\Roaming\Microsoft\Signatures\建立新邮件_files\image001.png
'src = "C:\用户\你的大名\AppData\Roaming\Microsoft\Signatures\建立新邮件_files\建立新邮件_files/image001.jpg
但我签名中图片还是不显示。
请问是不是还有其它设置？

civl · 发表于 2015-1-29 07:33

cccc5900 发表于 2015-1-24 17:10
你好，

我按你说的，用TXT打开HTML，并改了路径。

绝对引用图片的地址必须正确，按你写的，可能是有个符号不对“/”

cccc5900 · 发表于 2015-1-29 11:19

civl 发表于 2015-1-29 07:33
绝对引用图片的地址必须正确，按你写的，可能是有个符号不对“/”

多谢朋友！！！
我改了路径，现在在OUTLOOK端中可以显示签名图片了。
但网页中还是没法显示。
别外里面有个JPG. PNG.两种格式。是什么情况？

		自动登录	找回密码
密码			免费注册

[求助] 如何用VBA将邮件内容HTML化

评分

评分

最新热点 /1