请教，如何隐藏Access的菜单启动项

shepdog

我们经常在 菜单的“工具”->“启动项"，设置启动参数。
为了数据库安全，我希望能够在设置好了以后，用VBA语句，把”启动项“隐藏起来，在需要更改的时候，再修改VBA打开。

请问，怎么能够在VBA里写语句，隐藏启动项，或者使启动项失效，无法设置呢？

shepdog

题外话
我的安全设想是：
在启动项关闭 access特殊键，在VBA设置工程密码，然后再把启动项禁用。
这样，用户拿到数据库，也无法打开数据库对象，避免在表或视图直接修改数据；也无法查看VBA代码，从而提高数据库的安全性。进而把修改数据的绑定窗体改为非绑定窗体，尽量只通过VBA语句保存数据，进一步提高数据库的安全性。

rainless

窗体中设置如下
Private Sub Form_Open(Cancel As Integer)
  Application.RunCommand acCmdAppMinimize
DoCmd.Restore

公用模块可以设置如下
Public Sub AdminStartupProperties() '启动管理员权限
Const DB_Text As Long = 10
Const DB_Boolean As Long = 1
    ChangeProperty "StartupForm", DB_Text, "frmLoad"
    ChangeProperty "StartupShowDBWindow", DB_Boolean, True
    ChangeProperty "StartupShowStatusBar", DB_Boolean, True
    ChangeProperty "AllowBuiltinToolbars", DB_Boolean, True
    ChangeProperty "AllowFullMenus", DB_Boolean, True
    ChangeProperty "AllowBreakIntoCode", DB_Boolean, True
    ChangeProperty "AllowSpecialKeys", DB_Boolean, True
    ChangeProperty "AllowBypassKey", DB_Boolean, True
    ChangeProperty "AppTitle", DB_Text, gAppName
    ChangeProperty "AppIcon", DB_Text, CurrentProject.Path & "\wh.ico"
MsgBox "管理员权限已开启，请重新启动程序！"
End Sub

Public Sub UserStartupProperties() '用户权限
Const DB_Text As Long = 10
Const DB_Boolean As Long = 1

If CurrentDb().Properties("StartupShowDBWindow") = True Then
    ChangeProperty "StartupForm", DB_Text, "frmLoad"
    ChangeProperty "StartupShowDBWindow", DB_Boolean, False
    ChangeProperty "StartupShowStatusBar", DB_Boolean, False
    ChangeProperty "AllowBuiltinToolbars", DB_Boolean, True
    ChangeProperty "AllowFullMenus", DB_Boolean, False
    ChangeProperty "AllowBreakIntoCode", DB_Boolean, False
    ChangeProperty "AllowSpecialKeys", DB_Boolean, False
    ChangeProperty "AllowBypassKey", DB_Boolean, False
    ChangeProperty "AppTitle", DB_Text, gAppName
    ChangeProperty "AppIcon", DB_Text, CurrentProject.Path & "\wh.ico"
  End If
End Sub
Private Function ChangeProperty(strPropName As String, varPropType As Variant, varPropValue As Variant) As Integer
    '启动属性设置
    Dim dbs As Object, prp As Variant
    Const conPropNotFoundError = 3270

    Set dbs = CurrentDb
    On Error GoTo Change_Err
    dbs.Properties(strPropName) = varPropValue
    ChangeProperty = True

Change_Bye:
    Exit Function

Change_Err:
    If Err = conPropNotFoundError Then    ' Property not found.
        Set prp = dbs.CreateProperty(strPropName, _
            varPropType, varPropValue)
        dbs.Properties.Append prp
        Resume Next
    Else
        ' 未知错误。
        ChangeProperty = False
        Resume Change_Bye
    End If
End Function

shepdog

rainless 发表于 2012-11-30 09:15
窗体中设置如下
Private Sub Form_Open(Cancel As Integer)
  Application.RunCommand acCmdAppMinimize
...

非常感谢！
请问是在验证登陆密码后，按照权限的不同，分别调用AdminStartupProperties 过程和UserStartupProperties过程吗？

rainless

默认就UserStartupProperties，在需要的时候再调用AdminStartupProperties，也就是给管理员指定这个。

conddoo

请问，你用的是Access2007吗？

rainless

2003,07就一脑残的版本