批量修改word 中括号中的数字和文本

huibin

中括号内的内容有两种：

1  纯文本，比如[ABC], 修改后结果是[   ]。 即ABC的颜色变为白色。
2  带千分符的数字， 比如[1,200.04], 修改后的结果为[1,300]。即1200.04 *110%，然后取百位的整数，不带小数点。

跪谢！

sqhsqhli

Sub st5()
Dim s As String, f
With ActiveDocument.Content.Find
.Text = "\[[A-Z]@\]"
.Forward = True
.MatchWildcards = True
Do While .Execute
With .Parent.Duplicate
.Find.Execute findtext:="[A-Z]{1,}", MatchWildcards:=True
.Font.Color = vbWhite
End With
Loop
End With
With ActiveDocument.Content.Find
.Text = "\[[0-9\,.]@\]"
.Forward = True
.MatchWildcards = True
Do While .Execute
's = Mid(.Parent.Text, 2, Len(.Parent.Text) - 2)
s = Replace(Replace(.Parent.Text, "[", ""), "]", "")
f = Format(Format((s * 1.1) / 1000, "0.0") * 1000, "000,0")
.Parent.Text = "[" & f & "]"
.Parent.Collapse Direction:=wdCollapseEnd
Loop
End With
End Sub

kqbt

边学边练：

1. Sub pcl()
   
2.   Dim wRng As Range
   
3.   Set wRng = ActiveDocument.Content
   
4.   With wRng.Find
   
5.     .ClearFormatting
   
6.     .Replacement.ClearFormatting
   
7.     Do While .Execute(findtext:="\[*\]", MatchWildcards:=True)
   
8.       wRng.SetRange wRng.Start + 1, wRng.End - 1
   
9.       If IsNumeric(wRng) Then
   
10.         wRng = Format(Format((wRng * 1.1) / 1000, "#.#") * 1000, "#,###")
    
11.       Else
    
12.         wRng.Font.Color = wdColorWhite
    
13.       End If
    
14.       wRng.SetRange wRng.End, ActiveDocument.Content.End
    
15.     Loop
    
16.   End With
    
17. End Sub

复制代码

huibin

感谢楼上的大大，大力协助！

努力学习，膜拜

czr0373

kqbt 发表于 2012-4-20 10:36
边学边练：

如果括号内是纯数字，怎么把它全部删除？
比如，吞服杰出人物(21234123),删除除后成了：吞服杰出人物

kqbt

czr0373 发表于 2014-6-9 17:35
如果括号内是纯数字，怎么把它全部删除？
比如，吞服杰出人物(21234123),删除除后成了：吞服杰出人物

这种情况直接用“查找和替换”来替换就可以了。