如何修改VBA代码把"亩"换算为"公顷"？

r591

在翻译工作中，需要把亩（mu）换算为公顷（hectares）。
在WORD2003中使用通配符查找替换方法录制宏，得到代码如下：

Sub Mu2Ha()
'
' Mu2Ha Macro
' 宏在 2010-4-16 由 微软用户 录制
'
    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting
    With Selection.Find
        .Text = "([0-9]@)^32mu"             '亩数
        .Replacement.Text = "\1/15 hectares"   '亩数除以15应是公顷数
        .Forward = True
        .Wrap = wdFindContinue
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchByte = False
        .MatchAllWordForms = False
        .MatchSoundsLike = False
        .MatchWildcards = True
    End With
    Selection.Find.Execute Replace:=wdReplaceAll
End Sub

请教如何把"\1” 分离出来，再除以15，然后替换进去？

[ 本帖最后由 r591 于 2010-4-16 12:12 编辑 ]

sylun

可试试：
Sub Mu2Ha()
    Application.ScreenUpdating = False
    With Selection.Find
        .Parent.HomeKey wdStory
        .ClearFormatting
        .Text = "[0-9.]@^32mu>"
        .MatchWildcards = True
        Do While .Execute
            With .Parent
                .Text = Format(Val(.Text) / 15, "0.00") & " hectares"
                .Collapse wdCollapseEnd
            End With
        Loop
    End With
    Application.ScreenUpdating = True
End Sub

[ 本帖最后由 sylun 于 2010-4-16 17:04 编辑 ]

r591

专家就是专家。果然厉害！
另有一小问题：
There are 330 mu and 40 mu of land.
可以处理为：
There are 22.00 hectares and 2.67 hectares of land.
如何使之有小数时保留最多两位，如为整数时不要小数点？
是不是要改一下"0.00”？
多谢！

sylun

程序修改了一下，可试试：
Sub Mu2Ha()
    Dim a As Variant
    Application.ScreenUpdating = False
    With Selection.Find
        .Parent.HomeKey wdStory
        .ClearFormatting
        .Text = "[0-9.]@^32mu>"
        .MatchWildcards = True
        Do While .Execute
            With .Parent
                a = Format(Val(.Text) / 15, "0.00")
                If a Like "*00" Then
                    a = Format(a, "0")
                ElseIf a Like "*[1-9]0" Then
                    a = Format(a, "0.0")
                End If
                .Text = a & " hectares"
                .Collapse wdCollapseEnd
            End With
        Loop
    End With
    Application.ScreenUpdating = True
End Sub

r591

问题解决。多谢了！

tangqingfu

做个记号，收藏学习！
谢谢sylun兄的分享！

neaby

我修改了您的代码，请高手指正：
我们的问题相近，但是有小的不同。
请参见
http://club.excelhome.net/thread-613207-1-1.html
与我修改的部分，已经可以满足一部分要求，但是还有一部分我不会~~~
请指教~~

我的电子表1516

好资料，受益不少，收藏了！