请教EXCEL中特定的单元格的回车键事件怎样获取？

atse

如题，特定的单元格：比如C3,又或者是C3:C5区域,其它单元格均不触发事件，先谢谢了

来生缘

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Not Application.Intersect(Target, Range("C3:C5")) Is Nothing Then
        MsgBox Target.Address
    End If
End Sub

atse

谢谢楼上的好心人，但我要是不是Change事件，我想要的是在某单元格内按下Enter键的时候才触发的事件。

zldccmx

你要做的是：
1、在对应的工作表中插入一个文本框，并设置其属性为平板样式。(TextBox1.SpecialEffect 设为　fmSpecialEffectFlat )
2、在对应的工作表中，植入如下代码：

      '撰写:老朽
      '网址:http://Club.ExcelHome.net
      '日期:2010-3-29 下午 12:46:38
Private Sub TextBox1_Change()
    If TextBox1.Enabled Then
        Application.EnableEvents = False
        ActiveCell.Value = TextBox1.Value
        Application.EnableEvents = True
    End If
End Sub

      '撰写:老朽
      '网址:http://Club.ExcelHome.net
      '日期:2010-3-29 下午 12:46:39
Private Sub TextBox1_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    If KeyCode = 13 Then
        Application.EnableEvents = False
        TextBox1.TopLeftCell.Activate
        TextBox1.Visible = False
        MsgBox TextBox1.TopLeftCell.Address　'这里才开始加入你要做的事，前面和后面的代码都不能少
        Application.EnableEvents = True
    End If
End Sub

      '撰写:老朽
      '网址:http://Club.ExcelHome.net
      '日期:2010-3-29 下午 12:46:39
Private Sub TextBox1_LostFocus()
    TextBox1.Visible = False
End Sub

      '撰写:老朽
      '网址:http://Club.ExcelHome.net
      '日期:2010-3-29 下午 12:46:39
Private Sub Worksheet_SelectionChange(ByVal Target As Range )
    If Not Application.Intersect(Target, Range ("C3:C5")) Is Nothing Then
        Application.EnableEvents = False
        With TextBox1
            .Enabled = False
            .Value = Target.Value
            .Left = Target.Left
            .Width = Target.Width
            .Height = Target.Height
            .Top = Target.Top
            .Visible = True
            .Enabled = True
            .Activate
        End With
        Application.EnableEvents = True
    Else
        TextBox1.Visible = False
    End If
End Sub

zldccmx

一种变通办法，用文本框放在单元格上，用于捕捉回车事件！

atse

非常谢楼上两位，用“老朽”的方法解决了。

古都秋白

结合了楼上的内容，整合如下结果。
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Application.OnKey "{Enter}"
If Not Application.Intersect(Target, Range("C3:C5")) Is Nothing Then
     Application.OnKey "{Enter}", "test"
End If
End Sub

Sub test()
MsgBox "CCC"
End Sub

zyhui1961

古都秋白 发表于 2015-3-9 14:24
结合了楼上的内容，整合如下结果。
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
App ...

把我的宏加进去怎么就出错：
Sheets("Sheet2").Select
    Range("D5:I24").Select
    Selection.ClearContents '清除内容
    Sheets("Sheet1").Select

vistababy

代码有问题，回炉重造。。。。