换台电脑, recordset的Find方法就出错, 请教如何解决

waleywang

我做了一个Access的程序, 在子窗体中对某一文本框BeforeUpdate时做较验. 在我自己电脑上运行没任何问题, 但是发给用户后, 她运行时会出现" Find cannot be performed over the specified column,or compare operator is invalid."错误.
我仔细检查过了, 双方运行软环境是一样的:
Access2003(公司统一装的, 版本号也一样)
Reference中: ADO library 2.1 / DAO3.6也一样, 我甚至把这几个对应的文件都拷过去覆盖了她电脑上的文件.
但还是有问题.

请教怎么解决呢?

说明: 后台数据库是IBM AS400, 但这应该不影响吧? (至少在我的电脑上是没任何问题的)


附代码如下:

Private Sub InvoiceNo_BeforeUpdate(Cancel As Integer)
On Error GoTo Err_Handle:

    If IsNull(InvoiceNo) Or InvoiceNo = "" Or InvoiceNo = 0 Then
        MsgBox "发票号不能为空, 如果要删除本行, 请点右键, 选择删除记录即可"
        Cancel = True
        Exit Sub
    End If
     
     
    rsData.MoveFirst
    rsData.Find ("CFINV = " & CStr(InvoiceNo))
   
    If rsData.EOF Then
        MsgBox "错误的发票号码! 可能是已经登记过."
        Cancel = True
        Exit Sub
    End If
   
    OrderNo = rsData("CFORD")
    CustNo = rsData("CFCUST")
    CustName = rsData("ALPH")
    Select Case CStr(rsData("CFSTS"))
        Case "2"
            Correct = "Wrong"
        Case "1"
            Correct = "Correct"
        Case "0"
            Correct = "Unknow"
    End Select
                           
    If (rsData("INVQTY") <> rsData("ORDQTY")) And (rsData("INVTYP") = "O") Then
        Partial = "Y"
        MsgBox "注意,这是张Partial发票", vbCritical + vbOKOnly + vbApplicationModal
    End If

Exit_Sub:
    Exit Sub

Err_Handle:
    MsgBox Err.Description
End Sub

[ 本帖最后由 waleywang 于 2009-1-21 17:13 编辑 ]

waleywang

没办法, 急着用, 只好先用Command对象来解决了.

因为实际上每次只处理一条记录, 而且后台数据库已经保证了记录的唯一性, 所以就定义了一个command对象, 执行一条参数化的select的SQL语句, 把上面的代码改写为:

    With cmdData
        .CommandType = adCmdText
        .ActiveConnection = cnAS400
        .CommandText = "SELECT * FROM  Database.table WHERE Table.CFINV = ?"
    End With

    With rsData
        .ActiveConnection = cnAS400
        .CursorLocation = adUseClient
        .CursorType = adOpenKeyset
        .LockType = adLockOptimistic
    End With
    cmdData.Parameters(0).Value = InvoiceNo
    Set rsData = cmdData.Execute
这样再对rsdata做动作(有的话只有一条记录)

但是, 我还是不明白, 为什么好端端的换台电脑就不行了呢??? 没道理呀?  哪位高人能给个说法?

搞不明白, 实在是不甘心呐

[ 本帖最后由 waleywang 于 2009-1-22 14:13 编辑 ]

waleywang

发现用户电脑上装的是V4R4版本.
更新成V5R2后问题解决.

问题是, 还是不明白是何道理.

因为做Find时, 我在即时窗口里查过rsData, 记录集没问题. 难道说Recordset的特性与OLEDB特性相关??

有没有高手解释一下?

附: Connection对象和Recordset对象的实例化代码:
Sub GetConnectionAS400()     '建立到AS400的连接
On Error GoTo Err_Handle
    Set cnAS400 = New ADODB.Connection
    With cnAS400
        .CursorLocation = adUseClient
        .ConnectionTimeout = 15
        .Provider = "IBMDA400.DATASOURCE"
        .Open "Data Source=CN400A;User ID=" & strUserID & ";PassWord=" & strPassWord & ";"
    End With

Exit_Sub:
    Exit Sub

Err_Handle:
    blErrHappen = True
    strWrongMessage = "连接AS400出错, 以下是错误代码及描述."
    strWrongMessage = strWrongMessage & Err.Number & vbCrLf
    strWrongMessage = strWrongMessage & ErrMsg.Description
    MsgBox strWrongMessage
   
End Sub


Sub SetRsData(strConSQL As String)          '用于打开rsData记录集
On Error GoTo Err_Handle

    If Not (cnAS400.State = adStateOpen) Then
        cnAS400.Open
    End If
   
    With rsData
        .CursorLocation = adUseClient
        .CursorType = adOpenKeyset
        .LockType = adLockOptimistic
        rsData.Open strConSQL, cnAS400
    End With

Exit_Sub:
   
    Exit Sub
      
Err_Handle:
    blErrHappen = True
    strWrongMessage = "读取AS400数据出错!" & vbCrLf & Err.Description
    MsgBox strWrongMessage, vbCritical + vbOKOnly + vbApplicationModal
    Resume Exit_Sub

End Sub