[求助]一点关于表格的小问题！请教！

xs1064

我在文档中用录制宏的方法插入了2个表格，但是看那代码都是如下：

ActiveDocument.Tables.Add Range:=Selection.Range, NumRows:=1, NumColumns:= _
        3, DefaultTableBehavior:=wdWord9TableBehavior, AutoFitBehavior:= _
        wdAutoFitFixed
    With Selection.Tables(1)
        If .Style <> "网格型" Then
            .Style = "网格型"
        End If
        .ApplyStyleHeadingRows = True
        .ApplyStyleLastRow = True
        .ApplyStyleFirstColumn = True
        .ApplyStyleLastColumn = True
    End With
    Selection.EndKey Unit:=wdStory
    Selection.TypeParagraph
    ActiveDocument.Tables.Add Range:=Selection.Range, NumRows:=1, NumColumns:= _
        2, DefaultTableBehavior:=wdWord9TableBehavior, AutoFitBehavior:= _
        wdAutoFitFixed
    With Selection.Tables(1)
        If .Style <> "网格型" Then
            .Style = "网格型"
        End If
        .ApplyStyleHeadingRows = True
        .ApplyStyleLastRow = True
        .ApplyStyleFirstColumn = True
        .ApplyStyleLastColumn = True
    End With

为什么两个表格都是Tables(1)呢？

我如何向每个表格的列中插入文字呢？（VBA实现）

flPSJ0B0.rar (2.17 KB, 下载次数: 8)

2007-7-8 09:36 上传

点击文件名下载附件
[求助]一点关于表格的小问题！请教！

守柔

'* ＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋
'* Created By SHOUROU@ExcelHome 2007-7-8 16:48:06
'仅测试于System: Windows NT Word: 11.0 Language: 2052
'№ 0232^The Code CopyIn [ThisDocument-ThisDocument]^'
'* －－－－－－－－－－－－－－－－－－－－－－－－－－－－－
Option Explicit
Sub Example()
    Dim myTable As Table, myRange As Range
    With ActiveDocument
        '定义一个RANGE对象,为文档起始位置
        Set myRange = .Range(0, 0)
        '定义一个表格对象
        Set myTable = .Tables.Add(myRange, 1, 3)
        '为表格应用格式和样式,并插入文本
        With myTable
            .Style = "网格型"
            .Cell(1, 1).Range.Text = "ExcelHome"
            .Cell(1, 2).Range.Text = "Microsoft Office 2003"
            .Cell(1, 3).Range.Text = "Word 11.0"
            .Range.Font.Size = 12
            .Range.Font.Name = "Tahoma"
            .Range.ParagraphFormat.Alignment = wdAlignParagraphCenter
            .Range.Cells.VerticalAlignment = wdCellAlignVerticalCenter
        End With
        '在文档结束位置插入一个空白段落
        .Content.InsertAfter Chr(13)
        '定义一个RANGE对象为文档结束位置的前一个字符位置
        Set myRange = .Range(.Content.End - 1, .Content.End - 1)
        Set myTable = .Tables.Add(myRange, 1, 2)
        With myTable
            .Style = "网格型"
            .Cell(1, 1).Range.Text = "ExcelHome"
            .Cell(1, 2).Range.Text = "Microsoft Office 2003"
        End With
    End With
End Sub
'----------------------

xs1064

谢谢守柔版主的帮助，现在在表格中添加文字，能不能不用你说的那种方法，比如这样，

Set myRange = ActiveDocument.Tables(1).Cell(row, col).Range.Paragraphs(1).Range
  With myRange
      .InsertAfter Text:="请在各题目的答题区域内作答"
      .Font.Bold = wdToggle
      .Font.Size = 9
      .Font.Name = "宋体"
    End With

其中row,col代表行，列。因为我现在做了个窗体，由用户选择在表格的(row,col)添加文字，所以对于一个文档中，有两个表格，都是Tables(1)，我如何才能分别选定第一个表格或者第二个呢？都用ActiveDocument.Tables(1)吗？谢谢！

chylhr

QUOTE:

以下是引用xs1064在2007-7-10 15:17:32的发言：

谢谢守柔版主的帮助，现在在表格中添加文字，能不能不用你说的那种方法，比如这样，

Set myRange = ActiveDocument.Tables(1).Cell(row, col).Range.Paragraphs(1).Range
  With myRange
      .InsertAfter Text:="请在各题目的答题区域内作答"
      .Font.Bold = wdToggle
      .Font.Size = 9
      .Font.Name = "宋体"
    End With

其中row,col代表行，列。因为我现在做了个窗体，由用户选择在表格的(row,col)添加文字，所以对于一个文档中，有两个表格，都是Tables(1)，我如何才能分别选定第一个表格或者第二个呢？都用ActiveDocument.Tables(1)吗？谢谢！

一个文档中不能有两个表格都是Tables(1)。

第一个表格应该是ActiveDocument.Tables(1)；第二个表格应该是ActiveDocument.Tables(2)。

守柔

无论有多少个表格，光标所在的表格或者所选内容区域中的第一个表格，总是用Selection.Tables(1)来表示。