[求助]怎样用VBA去掉有嵌套的EQ域标记？

ssq1109

PSfXDzUB.rar (4.39 KB, 下载次数: 20)

2007-3-20 10:16 上传

点击文件名下载附件
[求助]怎样用VBA去掉有嵌套的EQ域标记？

最近为我们自办的网站提供WORD文档，但发现一些文档排得很不规范，如用EQ域排公式时，出现了多级嵌套的情况，虽然最终结果也是对的，但给人不专业、不规范的感觉。逐一手工修改当然不可能。能否用VBA代码进行规范。

在附件中有详细说明和测试实例。

守柔

未经精密测试，请参考：

'* ＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋
'* Created By SHOUROU@ExcelHome 2007-3-20 19:04:51
'仅测试于System: Windows NT Word: 11.0 Language: 2052
'№ 0185^The Code CopyIn [ThisDocument-ThisDocument]^'
'* －－－－－－－－－－－－－－－－－－－－－－－－－－－－－
Option Explicit
Option Compare Text
Sub myEQ()
    Dim oField As Field, oldCode As String, newCode As String
    Application.ScreenUpdating = False
    For Each oField In ActiveDocument.Fields
        With oField
            .Select
            If myCheck(Selection.Range) = True Then
                oldCode = VBA.Replace(.Code.Text, " ", "")
                newCode = VBA.Replace(oldCode, "EQ", "")
                newCode = VBA.Replace(newCode, Chr(19), "")
                newCode = VBA.Replace(newCode, Chr(21), "")
                .Code.Text = "EQ " & newCode
                .Update
            End If
        End With
    Next
    Application.ScreenUpdating = True
End Sub
'----------------------
Function myCheck(myRange As Range) As Boolean
'检查域代码是否为嵌套EQ域
    Dim oField As Field
    For Each oField In myRange.Fields
        If Selection.Fields.Count > 1 Then
            If oField.Type <> wdFieldFormula Then
                myCheck = False
                Exit Function
            Else
                myCheck = True
            End If
        Else
            myCheck = False
        End If
    Next
End Function
'----------------------

ssq1109

好的！谢谢守柔大侠！

基本达到要求，只是嵌套的EQ这两个字母如全为大写时尚可删掉，如果为另3种可能的写法：eq、Eq、eQ，则不能删掉。我在：

        newCode = VBA.Replace(oldCode, "EQ", "")下加了一句试了一下，但小写“eq”还是不能删掉。

        newCode = VBA.Replace(oldCode, "eq", "")

于是我在代码的前面加了下面的语句段：

    With ActiveDocument.Content.Find
        .ClearFormatting
        .MatchWildcards = True

       '先将EQ和\间的半角和全角空格规范成1个半角空格
        .Execute findtext:="([ 　]@)\\", replacewith:=" ^092", Replace:=wdReplaceAll
     End With

   '再将eq的大小写混写的情况一律规范成大写EQ
    With ActiveDocument.Content.Find
        .ClearFormatting
        .Execute findtext:="eq \", replacewith:="EQ \", Replace:=wdReplaceAll
     End With
可达目的，但此法明显不太简洁。且万一正文中其他地方在这样情况也会被误转换。

不知还有无更好的方法？

守柔

QUOTE:

以下是引用ssq1109在2007-3-20 21:23:49的发言：

好的！谢谢守柔大侠！

基本达到要求，只是嵌套的EQ这两个字母如全为大写时尚可删掉，如果为另3种可能的写法：eq、Eq、eQ，则不能删掉。我在：

你复制了代码中的Option Compare Text吗？

如果仍然存在此问题，请以此修改代码：

 oldCode = VBA.Replace(.Code.Text, " ", "", , , vbBinaryCompare)
 newCode = VBA.Replace(oldCode, "EQ", "", , , vbTextCompare)

ssq1109

神人也！

对不起，我先未复制那一句，现将代码复制到ThisDocument下运行正确。

ssq1109

守大侠的功力真是遥不可及！

你后改的代码运行也是正确的。

sylun

今天一直在围绕这道题进行学习，学了大半天，总算勉强做了出来。但只是入门层次，用的是土办法，没有美感可言。刚才学习了老大的代码，获益良多，印象深刻。