[求助]关于shift+F5的一些疑问

skyya

请问如何设置shift+F5只在两个位置来回切换?我在编辑文档时经常从前跳后,有没有方法可以自定义两个位置(用书签操做太繁),谢谢

yuyvtul

Dim i
Sub 光标来回()
If i = 0 Then
    Application.GoForward
    i = i + 1
Else
    Application.GoBack
    i = i - 1
End If
End Sub
这个好像可以，自定义为Shift+F5键或作一个工具按钮。
说明：
第一、首次试着用VBA，贻笑大方，错了，别羞我。
第二、楼主要求的办法方法我认为并不适用，因为在编辑过程中，有意无意地操作了鼠标和键盘，结果难以处理。倒不如将“回到上一编辑位置”和“回到下一编辑位置”两个拖到工具栏中或自定义键盘，用两个来分别向前向后操作。

[此贴子已经被作者于2007-2-27 23:11:54编辑过]

skyya

QUOTE:

以下是引用yuyvtul在2007-2-27 20:47:19的发言：

Dim i

第一、首次试着用VBA，贻笑大方，错了，别羞我。
第二、楼主要求的办法方法我认为并不适用，因为在编辑过程中，有意无意地操作了鼠标和键盘，结果难以处理。倒不如将“回到上一编辑位置”和“回到下一编辑位置”两个拖到工具栏中或自定义键盘，用两个来分别向前向后操作。

第一、太谦虚了

第二、你说的有道理，谢谢，再请问，shift+F5功能如何自定义的！它是如何实现的呢？

守柔

QUOTE:

以下是引用skyya在2007-2-27 20:21:13的发言：

请问如何设置shift+F5只在两个位置来回切换?我在编辑文档时经常从前跳后,有没有方法可以自定义两个位置(用书签操做太繁),谢谢

请使用:

Option Explicit
Dim TF As Boolean
Sub GoBack()
    If TF = False Then
        Application.GoBack
    Else
        Application.GoForward
    End If
    TF = Not TF
End Sub

其中的Sub GoBack过程称为修改WORD命令,有关修改WORD命令的解释,请搜索我的相关贴子.

将上述代码粘贴于当前文档或者NORAML.DOT的THISDOCUMENT或其下的标准模块中即可,完成后回后WORD文档中,按下SHIFT+F5,可测试效果.

有关SHIFT+F5的功能,请参:

GoBack 方法

将插入点在活动文档中最近进行过编辑操作的三个位置间移动，其作用等同于按 Shift+F5。

expression.GoBack

应用于Application对象.

yuyvtul

呵呵，学习了，更改Word命令。
原来，我只要将2楼的宏名改为Sub GoBack()就无需定义键盘了。
不过，可能楼主的意思我和守柔都理解错了：
①这种方式我无论如何都想不出意义，因为除非不进行其他操作，只“看”，否则不可能回到原来的位置。
②猜测楼主的意思是：
到了一个需要记住的编辑点(假定为A点)，按一个按钮，记住位置；
到了下一个编辑点，如果再按按纽(同一个或新一个)，原位置失效，记住新的位置。
定义shift+F5的功能为在两个位置之间切换。
不管楼主是否是这个意思，假定我需要这个功能，即两个代码：
一个是记住并更新编辑位置或插入点。
另一个是在记住的位置和当前位置间切换，怎么实现？
求教。

守柔

QUOTE:

以下是引用yuyvtul在2007-3-1 7:50:46的发言：
另一个是在记住的位置和当前位置间切换，怎么实现？
求教。

我只是做了一个示范，不知是否如田兄如说？

以下代码必须在类模块中，此处仍以“SHIFT+F5”快捷方式体现，当然，你可以直接指定其它的方式。

'* ＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋
'* Created By SHOUROU@ExcelHome 2007-3-1 17:36:03
'仅测试于System: Windows NT Word: 11.0 Language: 2052
'№ 0171^The Code CopyIn [ThisDocument-ThisDocument]^'
'* －－－－－－－－－－－－－－－－－－－－－－－－－－－－－
Option Explicit
Dim OldRange As Range, NewRange As Range, TF As Boolean, Cancel As Boolean
Private WithEvents wdApp As Word.Application
Private Sub Document_Open()
    Set wdApp = Word.Application
    Set NewRange = ActiveDocument.Range(0, 0)
End Sub
'----------------------
Private Sub wdApp_WindowSelectionChange(ByVal Sel As Selection)
    If Cancel = True Then Exit Sub
    Set OldRange = NewRange
    OldRange.SetRange NewRange.Start, NewRange.Start
    Set NewRange = Sel.Range
    NewRange.SetRange NewRange.Start, NewRange.Start
End Sub
'----------------------
Sub GoBack()
    Cancel = True
    If TF = False Then
        OldRange.Select
    Else
        NewRange.Select
    End If
    TF = Not TF
    Cancel = False
End Sub
'----------------------

示例文件：

96M9b8AV.rar (9.29 KB, 下载次数: 16)

2007-3-1 17:38 上传

点击文件名下载附件
[求助]关于shift+F5的一些疑问