请教版主关于文字替换的问题

cttc

版主:

      你好!

      我使用以下一段代码试图替换文字，但是在程序后却发现文本没有被替换，不知为什么，求教版主。

      Dim WordApp
   
    Set WordApp = CreateObject("Word.Application")
    WordApp.Selection.Find.ClearFormatting
    WordApp.Selection.Find.Replacement.ClearFormatting
    With WordApp.Selection.Find
        .Text = "11111111"
        .Replacement.Text = "2222222222222222222222"
        .Forward = True
        .Wrap = wdFindContinue
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchByte = True
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
    WordApp.Selection.Find.Execute Replace:=wdReplaceAll
    ActiveDocument.Save

c81

直接用selection行吧？可以省去新定义一个object。

守柔

QUOTE:

以下是引用cttc在2007-2-10 23:28:52的发言：

版主:

      你好!

      我使用以下一段代码试图替换文字，但是在程序后却发现文本没有被替换，不知为什么，求教版主。

      Dim WordApp
   
    Set WordApp = CreateObject("Word.Application")
    WordApp.Selection.Find.ClearFormatting
    WordApp.Selection.Find.Replacement.ClearFormatting
    With WordApp.Selection.Find
        .Text = "11111111"
        .Replacement.Text = "2222222222222222222222"
        .Forward = True
        .Wrap = wdFindContinue
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchByte = True
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
    WordApp.Selection.Find.Execute Replace:=wdReplaceAll
    ActiveDocument.Save

你的程序有问题了。

请看：

Set WordApp = CreateObject("Word.Application")
你这是创建了一个WORD 程序对象，这只是一个Word.Application

你没有打开任何文档，也就是说，ACTIVEDOCUMENT对象你还没有，你怎么可以查找与替换呢？

请加上如

WordApp.Documents.Open YourDocument

然后再进行替换。

如果把WordApp.Document.OPEN(YourDocument)返回给一个Document对象，则更好。

请参考以下两种方法：

'* ＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋
'* Created By SHOUROU@ExcelHome 2007-2-11 8:22:31
'仅测试于System: Windows NT Word: 11.0 Language: 2052
'№ 0152^The Code CopyIn [ThisDocument-ThisDocument]^'
'* －－－－－－－－－－－－－－－－－－－－－－－－－－－－－
Option Explicit
Sub Example()
'此处为工程引用MS WORD
    Dim WordApp As Word.Application, wdDoc As Word.Document
    Set WordApp = CreateObject("Word.Application")
    Set wdDoc = WordApp.Documents.Open("F:\TEST.DOC")
    With wdDoc
        With .Content.Find
            .ClearFormatting
            .Execute FINDTEXT:="1111111", REPLACEWITH:="22222222222", Replace:=wdReplaceAll
        End With
        .Save '保存文档
    End With
    WordApp.Visible = True '显示Word应用程序,如需退出,可加上WordApp.Quit
End Sub
'----------------------
Sub Example2()
'此处为创建一个后期绑定的Word对象
    Dim WordApp As Object, wdDoc As Object
    Set WordApp = CreateObject("Word.Application")
    Set wdDoc = WordApp.Documents.Open("F:\TEST.DOC")
    With wdDoc
        With .Content.Find
            .ClearFormatting
            .Execute FINDTEXT:="1111111", REPLACEWITH:="22222222222", Replace:=2
        End With
        .Save
    End With
    WordApp.Visible = True
End Sub
'----------------------

至于查找与替换的代码写法，我写的是比较简单的一种，你可以仍然按录制宏中的方式进行。请注意创建后期绑定对象时的Word常数(wdReplaceAll)应使用实际值代替（2）。

cttc

你给出的两端代码我分别把它们成如下：

Private Sub Form_Load()
Dim WordApp
Dim wdDoc
    Set WordApp = CreateObject("Word.Application")
    Set wdDoc = WordApp.Documents.Open("C:\doc1.doc")
    With wdDoc
        With .Content.Find
            .ClearFormatting
            .Execute FINDTEXT:="2", REPLACEWITH:="1", Replace:=wdReplaceAll
        End With
        .Save '保存文档
    End With
    'With wdDoc
        'With .Content.Find
            '.ClearFormatting
            '.Execute FINDTEXT:="2", REPLACEWITH:="1", Replace:=2
        'End With
        '.Save
    'End With

    WordApp.Visible = True '显示Word应用程序,如需退出,可加上WordApp.Quit

End Sub

当注释了第二种方法，运行程序，“2”没有被换成“1”，当注释了第一种方法，使用第二种方法，“2”被换成了“1”。仔细看了代码，发现就是Replace的值不同。请版主指教其中的不同。谢谢！

守柔

很显然，你使用的是创建后期绑定对象的方法。（定义为Object 或者 Variant类型）

因此，在代码中，无法取得对Microsoft Word Version Object Library的引用（相关常数），请仔细看我在三楼的回复。而在Word对象库中，

WdReplaceAll属于wdReplace类的常量，即然没有引用对象库，其常数自然无法正常识别，故不能正确替换。

wdReplaceAll常数的值为2，把它改为2就可以了。