如何使用vba隐藏word的标题栏？

wfstuman

如何使用vba隐藏word的标题栏，也就是word最上面的那个蓝色的栏？谢谢！1

c81

请搜索以前的，可能有好几个帖子。

在google中也可以找找。

gues1688

http://club.excelhome.net/viewthread.php?tid=194266

headbegger

在本论坛搜索过，还真没有隐藏WORD标题栏的例子，楼上的链接是隐藏EXCEL标题栏，宏代码中是通过EXCEL的Application.Hwnd用API函数实现的，但WORD的Apllication没有Hwnd属性，如何实现隐藏WORD标题栏呢？盼版主能解答！谢谢！！

headbegger

以前看到过将EXCEL扒个精光的帖子，使EXCEL只剩下编辑窗口，其他标题栏、菜单栏、工具栏、状态栏等全部隐藏了，但WORD能否做到呢？如何隐藏WORD标题栏还真有难度，请版主和各位达人也将WORD扒光看看，正需要解决这个问题。

konggs

原帖由 headbegger 于 2009-8-17 15:16 发表
在本论坛搜索过，还真没有隐藏WORD标题栏的例子，楼上的链接是隐藏EXCEL标题栏，宏代码中是通过EXCEL的Application.Hwnd用API函数实现的，但WORD的Apllication没有Hwnd属性，如何实现隐藏WORD标题栏呢？盼版主能解答 ...

一样的，只要拿到句柄就可以了。以下代码，改自上面链接的Excel

Word可以这样（此方法也可用于Excel）
'//查找需要的窗口
Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
'//取得窗口样式位
Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long) As Long
'//设置窗口样式位
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
'//重绘窗体标题栏
Private Declare Function DrawMenuBar Lib "user32" (ByVal hWnd As Long) As Long

'//以下定义常数及变量
Private Const GWL_STYLE = (-16)                 '窗口样式
Private Const WS_CAPTION = &HC00000                  '  WS_BORDER Or WS_DLGFRAME

'//****************************************************************************************************************************************

Sub BtResume_Click()
    Dim Istype As Long
    Dim hWnd As Long
    '//取得窗口样式位
    hWnd = FindWindow("OpusApp", vbNullString)
    Istype = GetWindowLong(hWnd, GWL_STYLE)
    '//窗体样式位: 原样式和标题栏
    Istype = Istype Or WS_CAPTION
    '//重设窗体样式位
    SetWindowLong hWnd, GWL_STYLE, Istype
    '//重绘窗体标题栏
    DrawMenuBar hWnd

End Sub

'//****************************************************************************************************************************************

Sub click1()

    Dim Istype As Long
    Dim hWnd As Long
    hWnd = FindWindow("OpusApp", vbNullString)
    'Excel改成  hWnd = FindWindow("XLMAIN", vbNullString)
    '//取得窗口样式位
    Istype = GetWindowLong(hWnd, GWL_STYLE)
    '//窗体样式位: 原样式无标题栏
    Istype = Istype And Not WS_CAPTION
    '//重设窗体样式位
    SetWindowLong hWnd, GWL_STYLE, Istype
    '//重绘窗体标题栏
    DrawMenuBar hWnd

End Sub

headbegger

谢谢konggs版主，赶紧试了一下，果然行！

headbegger

奇怪，为什么在打开时不能隐藏标题栏，
Private Sub Document_Open()
click1
MsgBox "ok"
End Sub

headbegger

更加奇怪的是，在WORD中，添加一个按钮“隐藏”，添加第二个按钮“显示”，打开文件后，第一次点击隐藏按钮竟然不能隐藏，点击第二次又可以了，而且两次获得的窗口句柄竟然不同，第一次获得的窗口文本为空，第二次可以获得正确的窗口标题文本。这是为什么呢？请版主不吝赐教，谢谢！！
Doc1.rar (11.55 KB, 下载次数: 44)

2009-8-23 10:16 上传

点击文件名下载附件

'模块中代码
'//查找需要的窗口
Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
'//取得窗口样式位
Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long) As Long
'//设置窗口样式位
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
'//重绘窗体标题栏
Private Declare Function DrawMenuBar Lib "user32" (ByVal hWnd As Long) As Long
Declare Function GetWindowText Lib "user32" Alias "GetWindowTextA" (ByVal hWnd As Long, ByVal lpString As String, ByVal cch As Long) As Long
'//以下定义常数及变量
Private Const GWL_STYLE = (-16)                 '窗口样式
Private Const WS_CAPTION = &HC00000                  '  WS_BORDER Or WS_DLGFRAME

'//****************************************************************************************************************************************

Sub BtResume_Click()
    Dim Istype As Long
    Dim hWnd As Long
    Dim MyStr As String
    'Create a buffer
    MyStr = String(100, Chr$(0))
    'Get the windowtext
   
   
    '//取得窗口样式位
    hWnd = FindWindow("OpusApp", vbNullString)
    Istype = GetWindowLong(hWnd, GWL_STYLE)
    '//窗体样式位: 原样式和标题栏
    Istype = Istype Or WS_CAPTION
    '//重设窗体样式位
    SetWindowLong hWnd, GWL_STYLE, Istype
    GetWindowText hWnd, MyStr, 100
    '//重绘窗体标题栏
    DrawMenuBar hWnd
    MsgBox hWnd & ",," & MyStr
End Sub

'//****************************************************************************************************************************************

Sub click1()

    Dim Istype As Long
    Dim hWnd As Long
    Dim MyStr As String
    'Create a buffer
    MyStr = String(100, Chr$(0))
    'Get the windowtext
   
    hWnd = FindWindow("OpusApp", vbNullString)
    'Excel改成  hWnd = FindWindow("XLMAIN", vbNullString)
    '//取得窗口样式位
    Istype = GetWindowLong(hWnd, GWL_STYLE)
    '//窗体样式位: 原样式无标题栏
    Istype = Istype And Not WS_CAPTION
    '//重设窗体样式位
    SetWindowLong hWnd, GWL_STYLE, Istype
    GetWindowText hWnd, MyStr, 100
    '//重绘窗体标题栏
    DrawMenuBar hWnd
    MsgBox hWnd & ",," & MyStr
End Sub

'ThisDocument中代码
Private Sub CommandButton1_Click()
    Call click1
End Sub

Private Sub CommandButton2_Click()
    Call BtResume_Click
End Sub

[ 本帖最后由 headbegger 于 2009-8-23 10:16 编辑 ]

pkpkyb

64位的行不通