[请教][问题更改]如何将光标定位到标题1?[已由老大解决]

keypress

最终要求:
 

1.当把某一段文字改为"标题1"样式时, 该段文字自动注入该活动文档的标题属性.

2.当把文档中的另一段文字改为 "标题1" 样式时, 跳出警告, 由编写者确定是否还要将这段文字设置为标题1(一般每个文档只有一个最高标题)

3.退而求其次--如何定位光标到1所在的段落?

参考代码(是为了将标题1的段落内容输入标题属性的):

Sub resetProperties()
ActiveDocument.BuiltInDocumentProperties(1) = ActiveDocument.Paragraphs(1)
On Error Resume Next
End Sub

代码的意思是将第一段文字设为标题, 现在要更改它, 要变成当我将其设定为 标题1 样式时, 才变为文档的标题.

困惑:

我使用selection.find对象, 无法定位到标题1所在的段落?

何解?

说明:

本人习惯于为每一个编写的文档输入详细的文档属性, 包括关键字, 以方便下一次的查找与使用.

期待好的解决方案! 先谢了

[此贴子已经被作者于2006-9-28 8:02:40编辑过]

守柔

请参考以下代码：

'* ＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋
'* Created By SHOUROU@ExcelHome 2006-9-23 8:17:25
'仅测试于System: Windows NT Word: 11.0 Language: 2052
'№ 0073^The Code CopyIn [ThisDocument-ThisDocument]^'
'* －－－－－－－－－－－－－－－－－－－－－－－－－－－－－
Option Explicit

Sub FileSave()
    Dim myRange As Range, N As Byte
    With ActiveDocument
        Set myRange = .Content
        With myRange.Find
            .ClearFormatting
            .Style = "标题 1"
            Do While .Execute = True
                N = N + 1
                If N = 2 Then
                    MsgBox "文档中段落应用标题 1样式超过了1个数量！", vbExclamation
                    Exit Do
                End If
            Loop
        End With
        If N = 0 Then
            MsgBox "文档中未找到段落应用标题 1样式，Word不进行保存操作！", vbExclamation
        Else
            .BuiltInDocumentProperties(wdPropertyTitle) = myRange.Paragraphs(1).Range.Text
            .Save
        End If
    End With
End Sub
'----------------------

说明：虽然Word有应用标题样式命令，但无法对于格式和样式任务窗格等样式设置命令进行响应，故使用保存命令来执行此操作，也就是当文档进行保存时，先执行检查标题样式，只有当标题样式为1个时，才能保存文档。

keypress

谢谢老大, 已下载, 等消化后再说话

keypress

一个新的问题:

当新建文档时, 点"保存", 会有对话框出现, 提示保存文件名, 此时点"取消", 会出现警告" 命令失败" ?

看来 Filesave()这个过程还是要好好研究一下的.

[此贴子已经被作者于2006-9-28 8:10:34编辑过]

守柔

请参考：

123456

Option Explicit

Sub FileSave()
    Dim myRange As Range, N As Byte
    With ActiveDocument
        Set myRange = .Content
        With myRange.Find
            .ClearFormatting
            .Style = "标题 1"
            Do While .Execute = True
                N = N + 1
                If N = 2 Then
                    MsgBox "文档中段落应用标题 1样式超过了1个数量！", vbExclamation
                    Exit Do
                End If
            Loop
        End With
        If N = 0 Then
            MsgBox "文档中未找到段落应用标题 1样式，Word不进行保存操作！", vbExclamation
        Else
            .BuiltInDocumentProperties(wdPropertyTitle) = myRange.Paragraphs(1).Range.Text
            If .Path <> "" Then
                .Save
            Else
                Word.Dialogs(wdDialogFileSaveAs).Show
            End If
        End If
    End With
End Sub

[此贴子已经被作者于2006-9-28 10:44:31编辑过]