请老师用公式，把两行相同的数显示出来，谢谢！

cartel · 发表于 2024-12-15 16:59

请老师用公式，把两行相同的数显示出来，谢谢！.zip (8.79 KB, 下载次数: 46)

lanjian229 · 发表于 2024-12-15 17:03

本帖最后由 lanjian229 于 2024-12-15 17:06 编辑

=TEXTJOIN(",",1,IFERROR(INDEX(TEXTSPLIT(H3,","),SORT(IFERROR(XMATCH(TEXTSPLIT(H4,,","),TEXTSPLIT(H3,",")),99))),""))

ww87725244 · 发表于 2024-12-15 17:10

=TEXTJOIN(",",,TOCOL(LET(x,REGEXEXTRACT(H4,"\d+",1),IF(FIND(x,H3),x)),3))

quqiyuan · 发表于 2024-12-15 17:14

=TEXTJOIN(",",,IF(ISNUMBER(FIND(","&TEXTSPLIT(H3,",")&",",","&H4&",")),TEXTSPLIT(H3,","),""))

复制代码

jerrike · 发表于 2024-12-15 18:29

本帖最后由 jerrike 于 2024-12-15 19:26 编辑

=TEXTJOIN(",",,IFNA(REGEXP(","&H3&",",",\K"&TEXTSPLIT(H4,",")&"(?=,)"),""))

复制代码

无关岁月 · 发表于 2024-12-15 20:08

=REGEXP(CONCAT(REGEXP(H3&",",REGEXP(H4&",",",",2,",|"))),".+(?=,$)")

复制代码

365

=TEXTJOIN(",",,MODE.MULT(--TEXTSPLIT(H3&","&H4,",")))

复制代码

秃头发师 · 发表于 2024-12-17 10:48

=TEXTJOIN(",",TRUE,IFERROR(VLOOKUP(TEXTSPLIT(H4,,","),TEXTSPLIT(H3,,","),1,FALSE),""))

你是那块小饼干 · 发表于 2024-12-17 10:56

=TOCOL(IF(BYROW(N(TEXTSPLIT(H3,",",,1)=TEXTSPLIT(H4,,",",1)),SUM),TEXTSPLIT(H4,,",",1),X),3)

复制代码

xxy1721 · 发表于 2024-12-17 11:55

TEXTJOIN(",",TRUE,IF(ISNUMBER(MATCH(REGEXP(H3,"[\d]+"),REGEXP(H4,"[\d]+"),0)),REGEXP(H3,"[\d]+"),""))

		自动登录	找回密码
密码			免费注册

[求助] 请老师用公式，把两行相同的数显示出来，谢谢！

评分

评分

评分

评分

评分

评分

评分

评分