请求大神帮忙简化我的代码-合并当前目录下所有工作簿

蓝毛象

求大神帮忙更新下我的代码，简化一下合并当前目录下所有工作簿。
Sub 合并当前目录下所有工作簿()
Dim wjm$, c%, pth$, Wb As Workbook, mx As Worksheet
Application.ScreenUpdating = False
Set mx = ThisWorkbook.ActiveSheet
pth = ThisWorkbook.Path & "\"
wjm = Dir(pth & "*.xls*")
Do While wjm = ""
  If wjm <> ThisWorkbook.Name Then
  Set Wb = Workbooks.Open(pth & wjm)
  c = mx.Range("a65336").End(xlUp).Row
   If c = 1 Then   '防止合并的工作簿第一行空着
       Set Rng = Range("a1").CurrentRegion.Offset(1, 0)
      Rng.Copy.mx.renge ("a" & c)
     Else
     Set Rng = Range("a1").CurrentRegion.Offset(3, 0)
     Rng.Copy.mx.renge ("a" & c + 1)
    End If
   Application.DisplayAlerts = False
   Wb.Close
   Application.DisplayAlerts = True
  End If
     wjm = Dir
Loop
mx.Columns.AutoFit
Application.ScreenUpdating = True
MsgBox "已完成"
End Sub

蓝桥玄霜

没有附件不能测试代码。
建议上传Excel表格附件来说明问题。

ykcbf1100

Set Rng = Range("a1").CurrentRegion.Offset(1, 0)，这里的范围是哪个表的？没指明。
Rng.Copy.mx.renge ("a" & c)，这明显是写错了，应该是这样吧：Rng.Copy mx.renge ("a" & c)
多处代码有问题。
还是应该有附件，没附件代码不方便测试的。

larer

Sub 合并当前目录下所有工作簿()
    Dim pth As String
    Dim wjm As String
    Dim Wb As Workbook
    Dim mx As Worksheet
    Dim c As Long
    Dim Rng As Range
   
    ' 禁用屏幕更新以提高性能
    Application.ScreenUpdating = False
    Application.DisplayAlerts = False
   
    ' 设置目标工作表为当前工作簿的活动工作表
    Set mx = ThisWorkbook.ActiveSheet
    pth = ThisWorkbook.Path & "\"
    wjm = Dir(pth & "*.xls*")
   
    Do While wjm <> ""
        If wjm <> ThisWorkbook.Name Then
            ' 打开工作簿
            Set Wb = Workbooks.Open(Filename:=pth & wjm)
            
            ' 找到目标工作表的最后一个已用行
            c = mx.Cells(mx.Rows.Count, 1).End(xlUp).Row
            
            ' 确定要复制的区域
            ' 如果第一行是空的，从第二行开始复制
            If Application.WorksheetFunction.CountA(Wb.Sheets(1).Range("A1")) = 0 Then
                Set Rng = Wb.Sheets(1).Range("A2").CurrentRegion
            Else
                Set Rng = Wb.Sheets(1).Range("A1").CurrentRegion
            End If
            
            ' 复制数据到目标工作表
            Rng.Copy Destination:=mx.Cells(c + 1, 1)
            
            ' 关闭打开的工作簿
            Wb.Close SaveChanges:=False
        End If
        wjm = Dir
    Loop
   
    ' 调整列宽
    mx.Columns.AutoFit
   
    ' 恢复屏幕更新和显示警告
    Application.ScreenUpdating = True
    Application.DisplayAlerts = True
   
    MsgBox "已完成合并当前目录下的所有工作簿。"
End Sub

蓝毛象

ykcbf1100 发表于 2024-12-12 19:30
Set Rng = Range("a1").CurrentRegion.Offset(1, 0)，这里的范围是哪个表的？没指明。
Rng.Copy.mx.renge  ...

感谢大佬

蓝毛象

larer 发表于 2024-12-12 20:56
Sub 合并当前目录下所有工作簿()
    Dim pth As String
    Dim wjm As String

感谢大佬，已实测有效。
但有个疑问，如果第一列只有一行有内容，其余列的内容有好多行，数据合并下来只有第一列，这个问题要怎么解决？

蓝毛象

蓝桥玄霜 发表于 2024-12-12 19:15
没有附件不能测试代码。
建议上传Excel表格附件来说明问题。

从事政教管理，附件上有学生信息，不方便上传，见谅

jjmysjg

larer 发表于 2024-12-12 20:56
Sub 合并当前目录下所有工作簿()
    Dim pth As String
    Dim wjm As String

Wb.Sheets(1)，只合并了各簿的第1个表，
Wb.Sheets(2)，合并了各簿的1、2表。
怎么能合并各簿所有表，并兼顾各簿表数不一？
谢谢大师

jjmysjg

蓝毛象 发表于 2024-12-13 08:50
从事政教管理，附件上有学生信息，不方便上传，见谅

把姓名改为张三、李四，把身份证改为123456，把单位改为国家教育部，把你的名改为董司长...只要格式不变就行。方面大师们就近解决你的问题。