模糊匹配时结果有些错的，如何修改公式

安然天涯 · 发表于 2024-11-19 08:36

需求：请教模糊匹配时结果有些错的，如何修改公式，感谢大神们指导

lanjian229 · 发表于 2024-11-19 08:48

模糊查找是要排序的

lachenfei · 发表于 2024-11-19 08:48

你使用的VLOOKUP去查 BY00-1752W0的时候，使用了TEXTBEFORE，-之前的内容，那你只是根据BY00*去查询，肯定会有差错的情况

lachenfei · 发表于 2024-11-19 08:50

建议加辅助列，然后用XLOOKUP进行查询，在返回B列的内容

mountain119 · 发表于 2024-11-19 08:51

本帖最后由 mountain119 于 2024-11-19 09:04 编辑

TEXTBEFORE函数加一个三参-1就行

=IFERROR(VLOOKUP(TEXTBEFORE(A2&"-","-",-1)&"*",年份变动!B:B,1,),"")

复制代码

或者用XLOOKUP函数查找（主要有无匹配时返回值的设定），低版本用LOOKUP嵌套IFNA也行

=XLOOKUP(1,FIND(A2,年份变动!$B$2:$B$26),年份变动!$B$2:$B$26,"")

复制代码

=IFNA(LOOKUP(1,FIND(A2,年份变动!$B$2:$B$26),年份变动!$B$2:$B$26),"")

复制代码

zwzc · 发表于 2024-11-19 08:51

=IFERROR(VLOOKUP(A3&"*",年份变动!B:B,1,0),"")

loirol · 发表于 2024-11-19 08:53

本帖最后由 loirol 于 2024-11-19 08:56 编辑

=IFERROR(VLOOKUP(TEXTBEFORE(A2&"$","$")&"*",年份变动!B:B,1,),"")

你匹配的数据本来就有-，又textbefore之后就剩最前面一节了

或者换一种转文本的方式，比如text

=IFERROR(VLOOKUP(TEXT(A2,"@")&"*",年份变动!B:B,1,),"")

leepoison · 发表于 2024-11-19 09:08

=IFERROR(MAP(A2:A86,LAMBDA(X,FILTER(年份变动!B2:B26,ISNUMBER(FIND(X,年份变动!B2:B26))))),"")

hxj119 · 发表于 2024-11-19 09:25

=IFNA(LOOKUP(1,0/FIND(SUBSTITUTE(A3,"-",),SUBSTITUTE(年份变动!$B$2:$B$26,"-",)),年份变动!$B$2:$B$26),"")

复制代码

hulin00 · 发表于 2024-11-21 09:16

本帖最后由 hulin00 于 2024-11-21 09:18 编辑

=IFERROR(VLOOKUP(A2&"*",年份变动!B:B,1,0),"")

复制代码

=IFERROR(INDEX(年份变动!$B$1:$B$26,SMALL(IF(ISNUMBER(FIND(A2,年份变动!$B$2:$B$26)),ROW(年份变动!$B$2:$B$26),""),1),),"")

复制代码

		自动登录	找回密码
密码			免费注册

[求助] 模糊匹配时结果有些错的，如何修改公式

评分

评分