给一列日期，每10个相同日期划分序号加1，日期不同也加1

风雨声点滴 · 发表于 2024-10-22 18:34

风雨声点滴 · 发表于 2024-10-22 18:35

求助大佬，谢谢

梦从东方来Frank · 发表于 2024-10-22 19:05

b3=IF(OR(COUNTIF($A$2:A3,A3)=11,COUNTIF($A$2:A3,A3)=21),B2+1,IF(A3=A2,B2,B2+1))

OR(COUNTIF($A$2:A3,A3)=11,COUNTIF($A$2:A3,A3)=21)，这段函数，如果会出现31或41，那么同理加进去。

mykitami · 发表于 2024-10-22 19:14

=DROP(REDUCE(0,A2:A60,LAMBDA(x,y,LET(a,TAKE(x,-1),VSTACK(x,IF((y=OFFSET(y,-1,0))*(SUM(N(a=x))<10),a,a+1))))),1)

风雨声点滴 · 发表于 2024-10-22 19:18

梦从东方来Frank 发表于 2024-10-22 19:05
b3=IF(OR(COUNTIF($A$2:A3,A3)=11,COUNTIF($A$2:A3,A3)=21),B2+1,IF(A3=A2,B2,B2+1))

OR(COUNTIF($A$2:A ...

结果出来有点小问题但还是要谢谢你

edwin11891 · 发表于 2024-10-22 20:03

本帖最后由 edwin11891 于 2024-10-22 20:12 编辑

拉火车：

=LET(s,DROP(REDUCE("",UNIQUE(A2:A60),LAMBDA(x,y,HSTACK(x,LET(a,FILTER(A2:A60,A2:A60=y),b,TRANSPOSE(WRAPROWS(a,10)),b)))),,1),t,DROP(REDUCE("",SEQUENCE(COLUMNS(s)),LAMBDA(x,y,VSTACK(x,IF(ISERROR(CHOOSECOLS(s,y)),1/0,y)))),1),TOCOL(t,3))

复制代码

世界客都 · 发表于 2024-10-22 22:38

B2下拉即可：
=IF((A1<>A2)+(MOD(COUNTIFS(A$1:A1,A2,B$1:B1,B1),10)=0),N(B1)+1,B1)

uneye2 · 发表于 2024-10-22 22:58

本帖最后由 uneye2 于 2024-10-23 01:33 编辑

uneye2 · 发表于 2024-10-22 23:09

=IF(ROW()=2,1,IF(OR(A2<>A1,COUNTIF($C$1:C1,C1)=10),C1+1,C1))

图片1.png

yibao2 · 发表于 2024-10-23 10:32

=IF((A1<>A2)+(COUNTIF(B$1:B1,B1)=10),N(B1)+1,B1)

		自动登录	找回密码
密码			免费注册

[求助] 给一列日期，每10个相同日期划分序号加1，日期不同也加1

评分

评分

评分

浏览过的版块