用VBA解决转移文件到文件夹中的问题

yangfx16900

文件与文件夹在同一路径下，文件与文件夹的名字分别在表格的A列与B列中，怎样用VBA代码将同一路径下的文件转移到相应的文件夹中？

z865593849

小凡、、、

大概这样吧

limonet

关键字：name

limonet

Sub limonet()
    Dim Path$, Arr As Variant, i%
    Path = ThisWorkbook.Path & "\"
    Arr = Range("A2:B" & Range("A" & Rows.Count).End(xlUp).Row)
    For i = 1 To UBound(Arr)
        Name Path & Arr(i, 1) As Path & Arr(i, 2) & "\" & Arr(i, 1)
    Next i
End Sub

quqiyuan

先检查文件是否存在，文件存在再文件夹是否存在，文件存在，文件夹不存在会创建，仅供参考。。。

quqiyuan

代码如下。。。
Sub test()
    Dim wb As Workbook, sht As Worksheet
    Set wb = ThisWorkbook
    Set sht = wb.Sheets("sheet1")
    p = wb.Path & "\"
    arr = sht.[a1].CurrentRegion
    Set fso = CreateObject("scripting.filesystemobject")
    For i = 2 To UBound(arr)
        If fso.FileExists(p & arr(i, 1)) Then
            If fso.FolderExists(p & arr(i, 2)) Then
                fso.movefile p & arr(i, 1), p & arr(i, 2) & "\"
            Else
                fso.CreateFolder (p & arr(i, 2))
                fso.movefile p & arr(i, 1), p & arr(i, 2) & "\"
            End If
        End If
    Next
    Set fso = Nothing
    Beep
End Sub

ykcbf1100

参与一下。

如果对应子目录不存在，则会新建

ykcbf1100

用fso会方便一点。