删除文件夹中其他工作薄中隐藏的工作表 （Excel版本2016））

scl2003921

请见我附件“删除文件夹中其他文件中的隐藏表格”中模块1，为什么VBA中wb.Worksheets.Count的结果总是多1，而在立即窗口中执行这句结果是对的？



------------------------------------以下为代码------------------------------------------------------
  Sub 删隐藏()
'删除其他工作薄中隐藏工作表
    Application.ScreenUpdating = False
    Application.DisplayAlerts = False
    With Application.FileDialog(msoFileDialogFolderPicker)
         .Title = "请选择工作簿所在的文件夹路径"
        If .Show Then
            Dim pathSelected As String, fn As String
            pathSelected = .SelectedItems(1)
            fn = Dir(pathSelected & "\*.xls*")
            
            Dim wb As Workbook
            Dim ws As Worksheet
            Dim t As Integer
            Dim i As Integer
            Do While fn <> ""
                Set wb = Workbooks.Open(pathSelected & "\" & fn, False)
               
               If wb.Name <> ThisWorkbook.Name Then
                   t = wb.Worksheets.Count          '就是这句有问题
                   MsgBox t
                    For i = 1 To t
                        If wb.Sheets(i).Visible <> xlSheetVisible Then
                           wb.Sheets(i).Visible = xlSheetVisible      '如果不加这句，隐藏的工作表无法删除
                            wb.Sheets(i).Delete
                        End If
                    Next i
                End If
               
                wb.Save
                wb.Close
                fn = Dir
            Loop
        End If
    End With
    Application.DisplayAlerts = True
    Application.ScreenUpdating = True
    MsgBox "已完成"
End Sub

ykcbf1100

隐藏的工作表是无法正常删除的，所以，只有先把隐藏工作表先显示出来才能删除了。

scl2003921

ykcbf1100 发表于 2024-9-17 11:20
隐藏的工作表是无法正常删除的，所以，只有先把隐藏工作表先显示出来才能删除了。

谢谢老师解惑

大灰狼1976

代码看下来好像有好几个问题，等下班后下载附件再仔细确认。

大灰狼1976

count数值问题没有发现，但有几个逻辑问题：
1、现在的逻辑，打开工作簿后判断与当前工作簿名是否相同，应该在打开前做判断；
2、用index遍历删除隐藏工作表时，应该倒序处理，不然会导致遗漏。

scl2003921

大灰狼1976 发表于 2024-9-19 09:48
count数值问题没有发现，但有几个逻辑问题：
1、现在的逻辑，打开工作簿后判断与当前工作簿名是否相同，应 ...

版主，没明白您的意思，能改造一下我的代码吗？谢谢！

scl2003921

ykcbf1100 发表于 2024-9-17 11:20
隐藏的工作表是无法正常删除的，所以，只有先把隐藏工作表先显示出来才能删除了。

老师，您说的这个问题我上面的代码已经解决，能否帮我解决一下第一个问题？谢谢！

ykcbf1100

scl2003921 发表于 2024-9-21 11:31
老师，您说的这个问题我上面的代码已经解决，能否帮我解决一下第一个问题？谢谢！

为什么会总是多1呢？多的应该是隐藏的表吧。

scl2003921

大灰狼1976 发表于 2024-9-18 17:01
代码看下来好像有好几个问题，等下班后下载附件再仔细确认。

谢谢老师，已经解决！


Sub 删隐藏()
    '删除其他工作薄中隐藏工作表
    Application.ScreenUpdating = False
    Application.DisplayAlerts = False
     Dim fn As String
    With Application.FileDialog(msoFileDialogFolderPicker)
         .Title = "请选择工作簿所在的文件夹路径"
        If .Show Then
            Dim pathSelected As String
            pathSelected = .SelectedItems(1)
            fn = Dir(pathSelected & "\*.xls*")
            Dim wb As Workbook
            Dim ws As Worksheet
            Dim t As Integer
            Dim i As Integer
            If fn Like ThisWorkbook.Name Then  '如果Dir首次选中的是thisworkbook则重新选择。这个判断原来在循环条件中，不知道为什么效果不行。
                fn = Dir
             End If
            Do While fn <> ""
               Set wb = Workbooks.Open(pathSelected & "\" & fn, False)
                    t = wb.Worksheets.Count
                     For i = t To 1 Step -1      '听取老师建议，采用倒序法，避免溢出
                        If wb.Sheets(i).Visible <> xlSheetVisible Then
                           wb.Sheets(i).Visible = xlSheetVisible
                            wb.Sheets(i).Delete
                        End If
                    Next i
                wb.Save
                wb.Close
                fn = Dir
            Loop
        End If
    End With
    Application.DisplayAlerts = True
    Application.ScreenUpdating = True
End Sub

山海风云轩

做个记号，学习学习