求助公式

yexfei1959 · 发表于 2024-9-12 17:20

求助公式设置，路过的大神帮我看看哦，谢谢

hugeinfo · 发表于 2024-9-12 17:24

=SUM((LEFT($C$2:$C$134,3)=$F2)*(RIGHT($C$2:$C$134,2)=G$1)*$D$2:$D$134)

沈默00 · 发表于 2024-9-12 17:59

=SUM((LEFT($C$2:$C$134,FIND("-",$C$2:$C$134)-1)=$F2)*(IFNA(REGEXP($C$2:$C$134,TEXTJOIN("|",,$G$1:$I$1)),"")=G$1)*$D$2:$D$134) 右拉下拉

浮生若梦~~~ · 发表于 2024-9-12 21:16

本帖最后由浮生若梦~~~ 于 2024-9-13 08:29 编辑

=SUM((LEFT($C$2:$C$134,FIND("-",$C$2:$C$134)-1)&RIGHT(C$2:$C$134,2)=$F2&G$1)*$D$2:$D$134)

yexfei1959 · 发表于 2024-9-13 07:00

浮生若梦~~~ 发表于 2024-9-12 21:16
=SUMIF($C:$C,$F2&"*"&G$1,$D:$D)

谢谢，QCH这行错了

yexfei1959 · 发表于 2024-9-13 07:01

沈默00 发表于 2024-9-12 17:59
=SUM((LEFT($C$2:$C$134,FIND("-",$C$2:$C$134)-1)=$F2)*(IFNA(REGEXP($C$2:$C$134,TEXTJOIN("|",,$G$1:$ ...

非常谢谢美女

mjm04 · 发表于 2024-9-13 09:42

本帖最后由 mjm04 于 2024-9-13 09:44 编辑

低版本：
=SUM($D$2:$D$228*ISNUMBER(FIND($F2,$C$2:$C$228))*ISNUMBER(FIND(G$1,$C$2:$C$228)))

=SUMIF($C$2:$C$228,$F2&"*"&G$1,$D$2:$D$228)
=SUMIFS($D$2:$D$228,$C$2:$C$228,$F2&"*"&G$1)

高版本
=SUM($D$2:$D$228*REGEXP($C$2:$C$228,$F2,1)*REGEXP($C$2:$C$228,G$1,1))

=SUM($D$2:$D$228*REGEXP($C$2:$C$228,$F2&".+"&G$1,1))

全部右拉，下拉， F4是 QCHH 也不影响的

你是那块小饼干 · 发表于 2024-9-13 10:33

=SUM(FILTER($D$2:$D$134,(ISNUMBER(FIND(G$1,$C$2:$C$134))*(ISNUMBER(FIND($F2,$C$2:$C$134)))),""))

复制代码

=SUMPRODUCT(ISNUMBER(FIND(G$1,$C$2:$C$134))*(ISNUMBER(FIND($F2,$C$2:$C$134))),$D$2:$D$134)

复制代码

左拉下拉

richardzhu15 · 发表于 2024-9-13 10:50

=SUMPRODUCT((IFNA(TEXTBEFORE($C:$C,"-"),"")=$J2)*(IFNA(TEXTAFTER($C:$C," "),"")=K$1),$D:$D)

169119191 · 发表于 2024-9-13 11:47

mjm04 发表于 2024-9-13 09:42
低版本：
=SUM($D$2:$D$228*ISNUMBER(FIND($F2,$C$2:$C$228))*ISNUMBER(FIND(G$1,$C$2:$C$228)))

高版本
=SUM($D$2:$D$228*REGEXP($C$2:$C$228,$F2,1)*REGEXP($C$2:$C$228,G$1,1))
你的这个在用正则时把qchh算到qch里面了

		自动登录	找回密码
密码			免费注册

[已解决] 求助公式