关于获取PDF数据

ke753951

日常工作中有一部分PDF的数据，想写一段VBA代码获取全部数据，
但是尝试了多次都失败了，完全找不到如何获取方法；


求助有没有大神给一段相关代码，学习学习！

ke753951

新人求教。

Peny2020

excel有个pdf转excel，是这个吗

celexcel2017

Peny2020 发表于 2024-4-25 14:42
excel有个pdf转excel，是这个吗

这个功能出来的数据，后续还要手动处理下
可以批量出来，对于不会编程的情况下，已经很不错了

LIUZHU

不如用Python试下，我也是依葫芦画瓢不怎么会

1. import PyPDF2
   
2. pdfreader=PyPDF2.PdfReader("1234.pdf","rb")
   
3. pdftext=''
   
4. for i in range(0,len(pdfreader.pages)):
   
5.     ipage=pdfreader.pages[i]
   
6.     pdftext+=ipage.extract_text()
   
7. print(pdftext)

复制代码

abchua1

Sub Imp_Into_XL(PDF_File As String)
    Dim AC_PD As New Acrobat.AcroPDDoc
    Dim AC_Hi As Acrobat.AcroHiliteList
    Dim AC_PG As Acrobat.AcroPDPage
    Dim AC_PGTxt As Acrobat.AcroPDTextSelect
    Dim WS_PDF As Worksheet
    Dim RW_Ct As Long
    Dim Col_Num As Integer
    Dim Li_Row As Long
    Dim Yes_Fir As Boolean
    Li_Row = Rows.Count
    Dim Ct_Page As Long
    Dim i As Long, j As Long, k As Long
    Dim T_Str As String
    Dim Hld_Txt As Variant
    RW_Ct = 0
    Col_Num = 1
    Application.ScreenUpdating = False
    Set AC_PD = New Acrobat.AcroPDDoc
    Set AC_Hi = New Acrobat.AcroHiliteList
    AC_Hi.Add 0, 32767
    With AC_PD
        .Open PDF_File
        Ct_Page = .GetNumPages
        If Ct_Page = -1 Then
            MsgBox "请确认PDF文件 '" & PDF_File & "'"
            .Close
            GoTo h_end
        End If
        For Each WS_PDF In Sheets
            Application.DisplayAlerts = False
            If WS_PDF.Name = "PDF读取到Excel" Then WS_PDF.Delete
            Application.DisplayAlerts = True
        Next
        Set WS_PDF = Worksheets.Add(, Worksheets(Sheets.Count))
        WS_PDF.Name = "PDF读取到Excel"
        Sheets("PDF读取到Excel").Columns("A:S").NumberFormatLocal = "@" '定义为文本格式
        For i = 1 To Ct_Page
            T_Str = ""
            Set AC_PG = .AcquirePage(i - 1)
            Set AC_PGTxt = AC_PG.CreateWordHilite(AC_Hi)
            If Not AC_PGTxt Is Nothing Then
                With AC_PGTxt
                    For j = 0 To .GetNumText - 1
                        T_Str = T_Str & .GetText(j)
                    Next j
                End With
            End If
            With WS_PDF
                If T_Str <> "" Then
                    Hld_Txt = Split(T_Str, vbCrLf)
                    Yes_Fir = True
                    For k = 0 To UBound(Hld_Txt)
                        RW_Ct = RW_Ct + 1
                        If Yes_Fir Then
                            RW_Ct = RW_Ct + 1
                            .Cells(RW_Ct, Col_Num).Value = "第" & i & "页"
                            RW_Ct = RW_Ct + 2
                            Yes_Fir = False
                        End If
                        If RW_Ct > Li_Row Then
                            RW_Ct = 1
                            Col_Num = Col_Num + 1
                        End If
                        T_Str = CStr(Hld_Txt(k))
                        If Left(T_Str, 1) = "=" Then T_Str = "'" & T_Str
                        .Cells(RW_Ct, Col_Num).Value = T_Str
                    Next k
                Else
                    RW_Ct = RW_Ct + 1
                    .Cells(RW_Ct, Col_Num).Value = "页面无文字 " & i
                    RW_Ct = RW_Ct + 1
                End If
            End With
        Next i
        .Close
    End With
    Application.ScreenUpdating = True
    'MsgBox "完成"
h_end:
    Set WS_PDF = Nothing
    Set AC_PGTxt = Nothing
    Set AC_PG = Nothing
    Set AC_Hi = Nothing
    Set AC_PD = Nothing
End Sub