用函数找出不同的值并从上到下排列出来

Superle! · 发表于 2024-3-11 21:33

本帖最后由 Superle! 于 2024-3-13 07:48 编辑

黄色背景单元格为函数填充区域G2:G21
D10:D39为数据源，数据是从上到下，依次找到不同的值，去除相同的值，从上到下排列出来。
看G10的六值是提取D10单元格的值六，G11的四值是提取D11单元格的值四，D11的单元格由于跟D10的值是相同的，所以忽略它。G12的十值是提取D13单元格的值十，依次找下去。
G21里为什么是空值，是因为D10:D39数据源里总共出现11个不同的值。

quqiyuan · 发表于 2024-3-11 21:58

=INDEX(D:D,SMALL(IF(MATCH($D$10:$D$39,$D$10:$D$39,)=ROW($10:$39)-9,ROW($10:$39)),ROW(A1)))

quqiyuan · 发表于 2024-3-11 21:59

2019可以用unique
=UNIQUE(D10:D39)

qydn · 发表于 2024-3-11 22:00

=IFERROR(INDEX($D$10:$D$39,SMALL(IF(MATCH($D$10:$D$39,$D$10:$D$39,0)=ROW($10:$39)-9,ROW($10:$39)-9,4^8),ROW(1:1)))&"","")

无关岁月 · 发表于 2024-3-11 22:06

低版

=LOOKUP(,0/FREQUENCY(0,COUNTIF(G$9:G9,D$10:D39)),D$10:D39)&""

复制代码

365

=GROUPBY(D10:D39,,,,0)

复制代码

Excel地板砖 · 发表于 2024-3-11 22:10

=IFERROR(LOOKUP(1,0/(COUNTIF(H$9:H9,$D$10:$D$39)=0),$D$10:$D$39),"")

Superle! · 发表于 2024-3-11 22:17

本帖最后由 Superle! 于 2024-3-11 22:19 编辑

无关岁月发表于 2024-3-11 22:06
低版

365

第1个函数，我用wps版本，第12个空值的出现0值了。适配下，谢谢

无关岁月 · 发表于 2024-3-11 22:36

Superle! 发表于 2024-3-11 22:17
第1个函数，我用wps版本，第12个空值的出现0值了。适配下，谢谢

不好意思，我这里没有wps，没法测试啊

		自动登录	找回密码
密码			免费注册

[已解决] 用函数找出不同的值并从上到下排列出来