请教一下横向的加权平均公式，相邻两列为一组，多组加权

tangteng822 · 发表于 2024-2-25 21:19

本帖最后由 tangteng822 于 2024-2-25 21:20 编辑

QQ截图20240225212008.png

如图所示，

我们一般使用加权平均公式，比较繁琐，期数越多，手动越麻烦，比如：

圆钢＞φ10，5~7期的加权平均公式为：
=(C3*D3+E3*F3+G3*H3)/(C3+E3+G3)

螺纹钢HRB400 直径＞φ16，8~11期的加权平均公式为：
=(I5*J5+K5*L5+M5*N5+O5*P5)/(I5+K5+M5+O5)

商品混凝土 C15，全部期数的加权平均公式为：
=(C8*D8+E8*F8+G8*H8+I8*J8+K8*L8+M8*N8+O8*P8)/(C8+E8+G8+I8+K8+M8+O8)

麻烦大佬看一下，有没有简便的公式呢，
就是根据后面的期数，来设置简便的公式，比如5~7期，8~11期，还有全部的期数

加权平均公式.zip (10.75 KB, 下载次数: 9)

mykitami · 发表于 2024-2-25 22:45

Q3公式，下拉
=LET(a,TEXTSPLIT(IF(R3="全部","5~11期",R3),{"~","期"},,1),b,INDEX(a,1),c,INDEX(a,2),d,N(OFFSET($B3,,MATCH(SEQUENCE(,c-b+1,b),--MID($C$1:$P$1,6,2),))),e,N(OFFSET($B3,,MATCH(SEQUENCE(,c-b+1,b),--MID($C$1:$P$1,6,2),)+1)),SUM(d*e)/SUM(d))

miaojohn45 · 发表于 2024-2-25 22:54

本帖最后由 miaojohn45 于 2024-2-25 23:11 编辑

=LET(期范围, IFERROR(TEXTSPLIT(R3,{"~","期","全部"},,1),{5,11}),
期开始, INDEX(期范围,1),
期结束, INDEX(期范围,2),
期序列, CEILING(SEQUENCE(,14,4.5,0.5),1),
期条件, ISNUMBER(VDB(,,期结束,期开始,期序列)),
工程量, FILTER(C3:P3,(C$2:P$2=C$2)*期条件),
信息价, FILTER(C3:P3,(C$2:P$2=D$2)*期条件),
SUMPRODUCT(工程量,信息价)/SUM(工程量)
)

复制代码

tangteng822 · 发表于 2024-2-25 22:56

mykitami 发表于 2024-2-25 22:45
Q3公式，下拉
=LET(a,TEXTSPLIT(IF(R3="全部","5~11期",R3),{"~","期"},,1),b,INDEX(a,1),c,INDEX(a,2),d, ...

大佬，如果后面的加权范围的值可以修改，是不是公式能简单一些，，比如把5~7期改成，其他的什么，能让公式简单一点呢

tangteng822 · 发表于 2024-2-25 23:10

miaojohn45 发表于 2024-2-25 22:54

太强了，这个公式

再扩展一下，如果是存在跨年份的情况，又该怎么处理呢？
图片1.png

加权平均公式（跨年）.zip (11.46 KB, 下载次数: 5)

tangteng822 · 发表于 2024-2-25 23:46

mykitami 发表于 2024-2-25 22:45
Q3公式，下拉
=LET(a,TEXTSPLIT(IF(R3="全部","5~11期",R3),{"~","期"},,1),b,INDEX(a,1),c,INDEX(a,2),d, ...

大佬，能不能看看，本贴5楼的情况呢，就是存在跨年份的期数

miaojohn45 · 发表于 2024-2-26 08:32

tangteng822 发表于 2024-2-25 23:10
太强了，这个公式

再扩展一下，如果是存在跨年份的情况，又该怎么处理呢？

=LET(期范围, IFERROR(MMULT(TEXTSPLIT(AD3,".",{"期","~"},1)-{2021,0},{12;1}),{5;17}),
期开始, INDEX(期范围,1),
期结束, INDEX(期范围,2),
期序列, CEILING(SEQUENCE(,26,4.5,0.5),1),
期条件, ISNUMBER(VDB(,,期结束,期开始,期序列)),
工程量, FILTER(C3:AB3,(C$2:AB$2=C$2)*期条件),
信息价, FILTER(C3:AB3,(C$2:AB$2=D$2)*期条件),
SUMPRODUCT(工程量,信息价)/SUM(工程量)
)

复制代码

		自动登录	找回密码
密码			免费注册

[求助] 请教一下横向的加权平均公式，相邻两列为一组，多组加权