求大佬，老师，VBA将word按特殊字符提取到excel

denggy

特殊字符是那个■号，以■为识别，将WORD里每个学校内容介绍提取到excel表格里，VBA能做到么？

denggy

denggy

gwjkkkkk

Option Explicit
Sub TEST()

    Dim ar, br, i&, r&, wdApp As Object, strFileName$, strPath$
   
    strPath = ThisWorkbook.Path & "\"
    strFileName = strPath & "yx2.docx"
    If Dir(strFileName) = "" Then MsgBox "指定的文件不存在，请检查！", vbExclamation: Exit Sub
   
    Application.ScreenUpdating = False
    On Error Resume Next
    Set wdApp = GetObject(, "Word.Application")
    If Err <> 0 Then
        Set wdApp = CreateObject("Word.Application")
    End If
   
    With wdApp.documents.Open(strFileName)
        ar = Split(.Content.Text, vbCr)
        ReDim br(UBound(ar) + 1, 1)
        br(0, 0) = "院校名称": br(0, 1) = "介绍"
        For i = 0 To UBound(ar)
            If InStr(ar(i), "■") Then
               r = r + 1
               br(r, 0) = ar(i)
            Else
                If Len(ar(i)) Then
                    If Len(br(r, 1)) = False Then
                        br(r, 1) = ar(i)
                    Else
                        br(r, 1) = br(r, 1) & vbCrLf & ar(i)
                    End If
                End If
            End If
        Next i
        .Close False
    End With
   
    Cells.Delete
    With [A1].Resize(r + 1, 2)
        .Value = br
        .Borders.LineStyle = xlContinuous
        .Rows(1).HorizontalAlignment = xlCenter
        .EntireRow.AutoFit
        .EntireColumn.AutoFit
        .EntireRow.AutoFit
    End With
   
    If Err <> 0 Then wdApp.Quit
    Set wdApp = Nothing
    Application.ScreenUpdating = True
    Beep
End Sub

gwjkkkkk

请参考。。。

denggy

gwjkkkkk 发表于 2024-2-8 19:32
请参考。。。

厉害啊，感激老师

smiletwo

denggy

gwjkkkkk 发表于 2024-2-8 19:31
Option Explicit
Sub TEST()

一步到位，都不需要改代码，666

denggy

smiletwo 发表于 2024-2-15 12:57

您的代码行数要简洁些，有没有源文件