求助，哪位大神能帮忙编个自动排编号的公式

zhangsq616 · 发表于 2024-1-19 12:10

要求：1、按照b列客户编号，重复客户为一个编号。
2、如果a列企业1和企业2都有客户3，那么企业2的客户3就需要增加一个编号，不能和企业1的客户3一个编号
3、企业和客户不限制排序，所以要按照整个区域是否重复编序号。

zhangsq616 · 发表于 2024-1-19 12:13

图片传重复了

，就不删了

良良 · 发表于 2024-1-19 12:43

本帖最后由良良于 2024-1-19 12:55 编辑

G2="JXSNWL-2024"&TEXT(RIGHT(IF(SUM((A$1:A1=A2)*(B$1:B1=B2)),VLOOKUP(A2&B2,IF({1,0},A$1:A1&B$1:B1,G$1:G1),2,),MAX(IFERROR(--RIGHT(G$1:G1,4),))+1),4),"0000")，三键。

世界客都 · 发表于 2024-1-20 10:14

本帖最后由世界客都于 2024-1-20 10:48 编辑

F2单元格输入按ctrl+shift+enter下拉即可：
=IFERROR(INDEX(F:F,MATCH(A2&B2,A$1:A1&B$1:B1,)),IF((A1<>A2)+(B1<>B2),"JXSNWL-2024"&TEXT(MAX(IFERROR(1--RIGHT(F$1:F1,4),1)),"0000"),F1))

简化一丢丢
=IFERROR(INDEX(F:F,MATCH(A2&B2,A$1:A1&B$1:B1,)),IF(AND(A2:B2=A1:B1),F1,"JXSNWL-2024"&TEXT(MAX(1-IFERROR(-RIGHT(F$1:F1,4),)),"0000")))

静听溪流 · 发表于 2024-1-20 10:41

=IFERROR(VLOOKUP(A2&B2,IF({1,0},A$1:A1&B$1:B1,G$1:G1),2,0),"JXSNWL-2024"&TEXT(ROUND(SUM(1/COUNTIFS(A$1:A2,A$2:A2,B$1:B2,B$2:B2)),),"0000"))

zhangsq616 · 发表于 2024-1-20 17:33

世界客都发表于 2024-1-20 10:14
F2单元格输入按ctrl+shift+enter下拉即可：
=IFERROR(INDEX(F:F,MATCH(A2&B2,A$1:A1&B$1:B1,)),IF((A1A2)+ ...

已经解决了，还是要感谢一下

zhangsq616 · 发表于 2024-1-20 17:34

静听溪流发表于 2024-1-20 10:41
=IFERROR(VLOOKUP(A2&B2,IF({1,0},A$1:A1&B$1:B1,G$1:G1),2,0),"JXSNWL-2024"&TEXT(ROUND(SUM(1/COUNTIFS(A ...

已经解决了，表示感谢

静听溪流 · 发表于 2024-1-20 17:44

zhangsq616 发表于 2024-1-20 17:34
已经解决了，表示感谢

好的不用客气

世界客都 · 发表于 2024-1-20 19:30

zhangsq616 发表于 2024-1-20 17:33
已经解决了，还是要感谢一下

可以右下角送花表示感谢

		自动登录	找回密码
密码			免费注册

[求助] 求助，哪位大神能帮忙编个自动排编号的公式

评分

评分

评分

最新热点 /1