如何实现将"/"符号前后的原料代码拆开然后统计数量

wcchuang0323 · 发表于 2023-4-13 14:42

本帖最后由 wcchuang0323 于 2023-4-15 09:51 编辑

我有一份清单，里面的备注栏位表示使用的原料代码及数量
使用多种原料时会用"/"斜线符号隔开
比如TL0302:0.075/TL0313:0.002，即是每单位使用TL0302原料0.075、TL0313原料0.002
请问如何实现一次性统计总共使用多少原料呢?

感谢!

无敌小猪猪 · 发表于 2023-4-13 20:11

不知道是不是这样，写了个简易的自定义函数

chxw68 · 发表于 2023-4-13 21:14

Sub test()
Dim r%, i%
Dim arr, brr
Dim d As Object
Set d = CreateObject("scripting.dictionary")
With Worksheets("導出所有基礎資料2-0")
r = .Cells(.Rows.Count, 1).End(xlUp).Row
arr = .Range("a2:e" & r)
For i = 1 To UBound(arr)
xm = Split(arr(i, 5), "/")
For j = 0 To UBound(xm)
xx = Split(xm(j), ":")
d(xx(0)) = d(xx(0)) + Val(xx(1))
Next
Next
.Range("j1").Resize(d.Count, 2) = Application.Transpose(Array(d.keys, d.items))
End With
End Sub

复制代码

chxw68 · 发表于 2023-4-13 21:15

详见附件。

lihaosh · 发表于 2023-4-13 23:37

Sub test1()
Dim r As Long, i As Long, j As Long
Dim arr As Variant, xm As Variant, xx As Variant
Dim d As Object
Set d = CreateObject("Scripting.Dictionary")
With Worksheets("導出所有基礎資料2-0")
r = .Cells(.Rows.Count, 1).End(xlUp).Row
arr = .Range("A2:E" & r).Value
For i = 1 To UBound(arr)
xm = Split(arr(i, 5), "/")
For j = 0 To UBound(xm)
xx = Split(xm(j), ":")
If d.Exists(xx(0)) Then
d(xx(0)) = d(xx(0)) + Val(xx(1))
Else
d.Add xx(0), Val(xx(1))
End If
Next j
Next i
Dim keysArr As Variant, itemsArr As Variant
keysArr = d.Keys
itemsArr = d.Items
.Range("J1").Resize(d.Count, 2).Value = Application.Transpose(Array(keysArr, itemsArr))
End With
End Sub

复制代码

wcchuang0323 · 发表于 2023-4-14 14:40

本帖最后由 wcchuang0323 于 2023-4-14 14:42 编辑

chxw68 发表于 2023-4-13 21:15
详见附件。

感谢帮助，加上了与数量相乘后就实现我要的效果了，也谢谢其他人的协助

chxw68 · 发表于 2023-4-14 18:39

修改好了。

wcchuang0323 · 发表于 2023-4-14 19:32

chxw68 发表于 2023-4-14 18:39
修改好了。

我也是自行加了 *arr(i, 3) 上去就修改完成了，小地方还能自行修改，但整体大方向实在是需要人提点，非常感谢您!

		自动登录	找回密码
密码			免费注册

[已解决] 如何实现将"/"符号前后的原料代码拆开然后统计数量

评分