PQ合并格式不一样工作表的问题，希望有老师能帮忙解答一下。

jiaodaoniu

有很多公司的excel表，公司数量会随时增减

每个表里有很多部门，部门数量也会随时增减
现在要把所有公司的excel表里，sheet名包含"部门"字样的数据按合并样式合并起来。
这个PQ怎么处理？望有老师能解答一下。
我只会合并格式完全一样的表，对这种字段数不一致的表一点头绪都没有。

Eric0236

let
    源 = Folder.Files("---你的文件夹地址---"),
    筛选 = Table.SelectRows(源, each Text.Contains([Name], "公司")),
    自定义 = Table.AddColumn(筛选, "自定义", each
        [a = Excel.Workbook([Content],true),
        b = Table.SelectRows(a, each Text.Contains([Name], "部门")),
        c = Table.SelectColumns(b, {"Name", "Data"}),
        d = Table.ExpandTableColumn(c, "Data", Table.ColumnNames(Table.Combine(c[Data]))),
        e =  Table.RenameColumns(d, {"Name", "部门"})
        ][e]),
    删除列 = Table.SelectColumns(自定义,{"Name", "自定义"}),
    展开 = Table.ExpandTableColumn(删除列, "自定义", Table.ColumnNames(Table.Combine(删除列[自定义]))),
    逆透视 = Table.UnpivotOtherColumns(展开, {"Name", "部门", "项目"}, "属性", "值"),
    重命名 = Table.RenameColumns(逆透视,{{"Name", "公司"}, {"属性", "月份"},{"值", "数量"}}),
    替换 = Table.ReplaceValue(重命名,".xlsx","",Replacer.ReplaceText,{"公司"})
in
    替换

lisongmei

asdfa sdfasdas fa

jiaodaoniu

谢谢各位老师

hbzql

let
    源 = Table.SelectRows(Folder.Contents("C:\Users\胡彬\Desktop\新建文件夹"),each not(Text.Contains([Name],"合并"))),
    自定义1 = Table.TransformColumns(源,{"Content",each Table.SelectColumns(Table.SelectRows(Excel.Workbook(_,true,true),each Text.Contains([Name],"部门")),{"Name","Data"})}),
    自定义2 = Table.RenameColumns(Table.ExpandTableColumn(Table.RenameColumns(Table.SelectColumns(自定义1,{"Content","Name"}),{"Name","公司名"}),"Content",{"Name","Data"}),{"Name","部门"}),
    自定义3 = Table.ExpandTableColumn(自定义2,"Data",List.Distinct(List.Combine(List.Transform(自定义2[Data],each Table.ColumnNames(_))))),
    自定义4 = Table.UnpivotOtherColumns(自定义3,{"公司名","部门","项目"},"月份","数量"),
    重排序的列 = Table.ReorderColumns(自定义4,{"公司名", "部门", "项目", "月份", "数量"})
in
    重排序的列