如何在 excel 中用 vba 给 word表格中插入斜下框线

王文铖

请问如何用 excel vba 给 word中的表格插入斜下框线或斜上框线？




我尝试在word中录制了代码，如下，并贴到 excel vba中，发现并没有效果！



求助各位大神，谢谢！

守候_CJ

一、后期引用其他程序，里面的各种参数需要明确，常数和对象均需要明确指定。或者改为前期引用。
二、代码

1. Sub test1()
   
2.     WordFileName = ThisWorkbook.Path & "\测试文档.docx"
   
3.     Set objWord = CreateObject("Word.Application")
   
4.     With objWord
   
5.         Set objDoc = .Documents.Open(WordFileName)
   
6.         With objDoc.Tables(1)
   
7.             
   
8.             a = .Cell(1, 1).Range.Text
   
9.             Debug.Print a
   
10.             
    
11.             .Cell(1, 2).Range.Select
    
12.             With objWord.Selection.Cells.Borders(-8)
    
13.                 .LineStyle = 1
    
14.                 .LineWidth = 4
    
15.                 .Color = -16777216
    
16.             End With
    
17.             
    
18.         End With
    
19.     End With
    
20.     objDoc.Close: objWord.Quit
    
21.     Set objDoc = Nothing
    
22.     Set objWord = Nothing
    
23. End Sub

复制代码

gwjkkkkk

Option Explicit
Sub TEST()
    Dim wdApp As Word.Application, wdDoc As Word.Document
    Dim i&, j&, strFileName$, strPath$
   
    strPath = ThisWorkbook.Path & "\"
    strFileName = strPath & "测试文档.docx"
    If Dir(strFileName) = "" Then MsgBox "指定的文件不存在，请检查！", vbExclamation: Exit Sub
   
    Set wdApp = New Word.Application
    Set wdDoc = wdApp.documents.Open(strFileName)
    With wdDoc
        With .Tables(1)
            For i = 1 To .Rows.Count
                For j = 1 To .Columns.Count
                    With .Cell(i, j).Range.Borders(wdBorderDiagonalUp)
                       .LineStyle = Options.DefaultBorderLineStyle
                       .LineWidth = Options.DefaultBorderLineWidth
                    End With
                Next j
            Next i
        End With
        .Close True
    End With

    wdApp.Quit
    Set wdApp = Nothing: Set wdDoc = Nothing
    Beep
End Sub

gwjkkkkk

请楼主参考。。。

王文铖

gwjkkkkk 发表于 2023-2-21 21:08
Option Explicit
Sub TEST()
    Dim wdApp As Word.Application, wdDoc As Word.Document

谢谢，代码有用，但是我需要的是后绑定，一定要先引用word库吗

王文铖

守候_CJ 发表于 2023-2-21 20:47
一、后期引用其他程序，里面的各种参数需要明确，常数和对象均需要明确指定。或者改为前期引用。
二、代码 ...

这个代码不用事先引用库，更适合我的引用场景，谢谢啦

守候_CJ

王文铖 发表于 2023-2-21 22:28
这个代码不用事先引用库，更适合我的引用场景，谢谢啦

gwjkkkkk

王文铖 发表于 2023-2-21 22:22
谢谢，代码有用，但是我需要的是后绑定，一定要先引用word库吗

通过excel操作word，写代码时可通过事前引用，这样相关属性可以进行提示，发布时可以改成事后引用，看下是否达到目的，因为事后引用有些属性并不起作用，这是需要注意的地方。。。

王文铖

gwjkkkkk 发表于 2023-2-21 22:40
通过excel操作word，写代码时可通过事前引用，这样相关属性可以进行提示，发布时可以改成事后引用，看下 ...

谢谢，代码还是很有帮助的