vb.net中打开文本文件，读取的汉字是乱码

prcstone

vb.net中用“     File.ReadAllLines(fileName, Encoding.Default)    ”打开文本文件（文本文件的原编码为ANSI），读取的汉字是乱码，而且程序结束后，文本文件再打开就成UTF-8格式了。

有什么办法？正确读取，谢谢。

prcstone

解决办法好像只能被动地先把文本文件保存成UTF-8格式

dxq92

理论得逻辑应该是 先确认文档编码，然后在用指定编码打开把

dxq92

或者：

安装 nuget:
System.Text.Encoding.CodePages

1. Encoding.RegisterProvider(CodePagesEncodingProvider.Instance)
   
2. 
   
3. Dim sw As StreamReader = New StreamReader(fpath , encoding:=Encoding.GetEncoding("GB2312"))

复制代码

mjzxlmg

#Region "BytesFormatText"
    ''' <summary>
    ''' BytesFormatText
    ''' </summary>
    ''' <param name="Bytes"></param>
    ''' <returns>String</returns>
    <Runtime.CompilerServices.Extension>
    Private Function BytesFormatText(Bytes() As Byte) As String
        Dim len As Integer = Bytes.Length
        If len >= 3 AndAlso Bytes(0) = &HEF AndAlso Bytes(1) = &HBB AndAlso Bytes(2) = &HBF Then Return Encoding.UTF8.GetString(Bytes, 3, len - 3)
        Dim cs() As Integer = {7, 5, 4, 3, 2, 1, 0, 6, 14, 30, 62, 126}
        For i As Integer = 0 To len - 1
            Dim bits As Integer = -1
            For j As Integer = 0 To 5
                If CInt(Bytes(i)) >> cs(j) = cs(j + 6) Then
                    bits = j
                    Exit For
                End If
            Next
            If bits = -1 Then Return Encoding.Default.GetString(Bytes)
            Do While bits > 0
                bits -= 1
                i += 1
                If i = len OrElse CInt(Bytes(i)) >> 6 <> 2 Then Return Encoding.Default.GetString(Bytes)
            Loop
        Next
        Return Encoding.UTF8.GetString(Bytes)
    End Function
#End Region
#Region "读取文件流"
    ''' <summary>
    ''' 读取文件流
    ''' </summary>
    ''' <param name="path">文件地址</param>
    ''' <returns>返回Byte文件流</returns>
    <Runtime.CompilerServices.Extension>
    Public Function ReadFile(path As String) As String
        Using FileStream As New FileStream(path, FileMode.Open, FileAccess.Read)
            Try
                With FileStream
                    Dim Buffur(.Length - 1) As Byte
                    .Read(Buffur, 0, .Length)
                    .Seek(0, SeekOrigin.Begin)
                    Return Buffur.BytesFormatText
                End With
            Catch ex As IOException
                Throw New IOException(ex.Message)
                Return Nothing
            End Try
        End Using
    End Function
#End Region