多条件查询

Carlwantsmore · 发表于 2023-1-5 14:18

本帖最后由 Carlwantsmore 于 2023-1-5 14:40 编辑

需要根据多个条件返回值，其中前两个条件需要精确匹配，最后一个条件需要取最接近的值，尝试了很多办法没有解决，希望帮忙看看有没有好的思路？附件发不了，简单模拟了一下数据如图

tchh666 · 发表于 2023-1-5 14:34

上传附件哦。。。

Carlwantsmore · 发表于 2023-1-5 14:41

tchh666 发表于 2023-1-5 14:34
上传附件哦。。。

压缩了可以发了。。刚刚Excel文件拖不进来

hugeinfo · 发表于 2023-1-5 14:46

本帖最后由 hugeinfo 于 2023-1-5 14:47 编辑

=INDEX(D:D,MATCH(MIN(IFERROR( ABS( IF(($A$2:$A$28=G2)*($B$2:$B$28=H2),$C$2:$C$28,"")-I2 ),9^9)),ABS(($A$2:$A$28=G2)*($B$2:$B$28=H2)*$C$2:$C$28-I2),)+1) 有点啰嗦

tchh666 · 发表于 2023-1-5 14:54

=INDEX(D:D,MATCH(1,FREQUENCY(-9^9,-($A$2:$A$28=F2)*($B$2:$B$28=G2)*($C$2:$C$28<=H2)*$C$2:$C$28),)+1)

复制代码

hcm19522 · 发表于 2023-1-5 14:58

I2{=INDEX(D:D,RIGHT(MAX(IF((A$2:A$16=F2)*(B$2:B$16=G2)*(C$2:C$16<=H2),C$2:C$16)/1%+ROW($2:$16)),2))

Carlwantsmore · 发表于 2023-1-5 15:03

hugeinfo 发表于 2023-1-5 14:46
=INDEX(D:D,MATCH(MIN(IFERROR( ABS( IF(($A$2:$A$28=G2)*($B$2:$B$28=H2),$C$2:$C$28,"")-I2 ),9^9)),ABS( ...

谢谢，可行的，我想到了这个思路，但是用index small if没写出来，谢谢你

tchh666 · 发表于 2023-1-5 15:04

本帖最后由 tchh666 于 2023-1-5 15:06 编辑

=LOOKUP(1,0/FREQUENCY(0,((A$2:A$28&B$2:B$28=F2&G2)*C$2:C$28-H2)^2),$D$2:$D$28)

复制代码

Carlwantsmore · 发表于 2023-1-5 15:08

tchh666 发表于 2023-1-5 15:04

学到了，Lookup还是理解的不够深呀。。。十分感谢，这两个解法都值得我好好研究一下了

		自动登录	找回密码
密码			免费注册

[求助] 多条件查询

评分